Ввод и вывод матрицы, Простой вопрос Опции

[Shmaniche]

Застопорился на простом – ввод и вывод матрицы – когда составлял одну программу. Хочу сделать так чтобы матрица красиво выводилась, но после ввода значений в вектор B, в нем выводятся одни нули. То есть матрица A выводиться правильно, а в векторе B одни нули. Где допустил ошибку не могу найти. Помогите разобраться. Вот код ввода и вывода:

program vv;

uses crt;
const c=10;
 type mat=array [1..c, 1..c] of real;
      vec=array  [1..c] of real;
  var A: mat;
      B: vec;
      n: integer;

{Процедура ввода матрицы}
procedure Matr_Vvod(n:integer; var A:mat; B:vec);
 var i, j: integer;
 begin
  writeln('Вводите коэфф-ты матpицы A по стpокам нажимая ENTER:');
  for i:=1 to n do
   for j:=1 to n do
    begin
     write ('A[',i,',',j,']=');
     read(A[i,j]);
     end;
  writeln;
   writeln('Введите вектоp В свободных членов нажимая ENTER:');
    for i:=1 to n do
     begin
      write ('B[',i,']=');
      read(B[i]);
     end;
 end;

{Процедура вывода матрицы}
procedure Matr_Vivod(n: integer; var A:mat; B:vec);
 var i, j: integer;
  begin
   writeln('Исходная матpица:');
   for i:=1 to n do
    begin
     for j:=1 to n do
        write (A[i, j]:5:3,' ':2); {Вывод матрицы с отступами}
        write (B[i]:5:3,' ':2); {Вывод вектора с отступами}
        writeln;
    end;
   end;

 begin
  clrscr;

  writeln('Вывод матрицы.');
  writeln;
  writeln('Введите размерность матрицы и нажмите ENTER:');
  readln(n);
  writeln;

  Matr_Vvod(n,A,B); {Ввод матрицы}
  writeln;
  Matr_Vivod(n,A,B); {Вывод матрицы}
  writeln;

 readkey;

end.

[Федосеев Павел]

procedure Matr_Vvod(n:integer; var A:mat; var B:vec);

[Shmaniche]

procedure Matr_Vvod(n:integer; var A:mat; var B:vec);

Хорошо! Но при таком вводе вот эта программа работает неправильно:

program Zeyd;
{Вычисление СЛАУ методом Зейделя}

uses crt;
const c=10;
 type mat=array [1..c, 1..c] of real;
      vec=array  [1..c] of real;
  var A: mat;
      B: vec;
      i,l,m,n: integer;
      e: real;

{Процедура ввода матрицы}
procedure Matr_Vvod(n:integer; var A:mat; var B:vec);
 var i, j: integer;
 begin
  writeln('Вводите коэфф-ты матpицы A по стpокам нажимая ENTER:');
  for i:=1 to n do
   for j:=1 to n do
    begin
     write ('A[',i,',',j,']=');
     read(A[i,j]);
     end;
  writeln;
   writeln('Введите вектоp В свободных членов нажимая ENTER:');
    for i:=1 to n do
     begin
      write ('B[',i,']=');
      read (B[i]);
     end;
 end;

{Процедура вывода матрицы}
procedure Matr_Vivod(n: integer; var A:mat; var B:vec);
 var i, j: integer;
  begin
   writeln('Исходная матpица:');
   for i:=1 to n do
    begin
     for j:=1 to n do
        write (A[i, j]:5:3,' ':2); {Вывод матрицы с отступами}
        write (B[i]:5:3,' ':2); {Вывод вектора с отступами}
        writeln;
    end;
   end;

{Процедура вычисления СЛАУ методом Зейделя}
procedure Seid(var n,m,l:integer; var A:mat; var B:vec; e:real);
 var i,j,k,k1,n1:integer;
     s:real;
 begin
  for k:=1 to m do
   begin
    l:=k;
    for i:=1 to n do
     begin
      s:=A[i, n+1];
      for j:=1 to n do
       s:=s - a[i,j] * B[j];
       s:=s / a[i,i];
       B[i]:=B[i] + s;
       if abs(s) > e then l:=0;
     end;
     if l<>0 then exit;
   end;
 end;

 begin
  clrscr;

  writeln('Вычислить СЛАУ методом Зейделя.');
  writeln;
  writeln('Введите колич-во неизвестных величин "n" и нажмите ENTER:');
  readln(n);
  writeln;
  writeln('Введите максимально допустимое кол-во интераций "m":');
  readln(m);
  writeln;
  writeln('Задайте погрешность решений "e":');
  readln(e);
  writeln;

  Matr_Vvod(n,A,B); {Ввод матрицы}
  writeln;
  Matr_Vivod(n,A,B); {Вывод матрицы}
  writeln;

  Seid(n,m,l,A,B,e); {Вычисление СЛАУ методом Зейделя}

  if l<>0 then
   begin
    writeln('ОТВЕТ:');
     for i:=1 to n do
      writeln('X', i,' = ',B[i]:3:4);
      writeln;
      writeln(l:2,' интерации(я).');
   end
  else
   writeln('Интерации все.');

 readkey;

end.

Если решить систему уравнений методом Зейделя:
10x1+x2+x3=12;
2x1+10x2+x3=13;
2x1+2x2+10x3=14;

Расш-ая матрица:
10 1 1 | 12
2 10 1 | 13
2 2 10 | 14

То должен получиться след. примерный ответ:
x1=0.9992; x2=1.0054; x3= 0.9991; После 5 итераций с погрешностью решений 1,
а выходит следующее:
x1=0.0062; x2=-0.0024; x3=-0.0008; Что очень далеко до правильного ответа. :(

Сообщение отредактировано: Shmaniche - 14.04.2013 18:37