Обмен данными между двумя объектами, Передать значение переменной Опции

[comanche]

Добрый день, товарищи! Дело такое:

Имеются два независимых объекта. Как заставить их работать сообща, тобишь чтобы переменная одного объекта (в моём случае - массив) могла быть доступна другому объекту при описании?
Пока что вижу всего лишь один способ - объединить оба объекта в один

[volvo]

Пример готовых отдельных объектов приведи, и ЧТО ты хочешь чтобы было доступно - тоже... Посмотрим, как можно это реализовать... Кстати, для какого компилятора, уточни...

чтобы переменная одного объекта (в моём случае - массив) могла быть доступна другому объекту при описании?

Это как "при описании"?

[comanche]

"При описании" я имел в виду, что уже при описании выдаёт ошибку, то что второму объекту не известны методы первого.

Вот здесь, например, я хочу вывести на экран массив, хранящийся в первом объекте на экран при помощи второго объекта.

P.s. использую TMT, но на TP тоже должно пахЫть

Type

  TPlayGround = Array [1..MaxRows, 1..MaxColumns] OF Byte; {6 columns, 6 rows}

// TGame Interface section

  TGame = object
  private
    PG: TPlayGround;
  public
    Constructor Init;
    Destructor Done;
    Function GetPG: TPlayGround;
  end;

// TMenu Interface section

  TMenu = object
    Constructor Init;
    Destructor Done;
    Procedure DrawPlayGround;
  end;

[volvo]

я хочу вывести на экран массив, хранящийся в первом объекте на экран при помощи второго объекта.

Да ты покажи, КАК ты хочешь вызывать это... У меня никакой ошибки не показывает, ИБО НЕТ ЕЕ в том коде, который ты привел !

[comanche]

Вот .PAS файл, ошибка на 91-й строке:

Качать

[volvo]

Так устроит:

Const
  MaxColumns = 6;
  MaxRows = 6;

Type
  TPlayGround = Array [1..MaxRows, 1..MaxColumns] OF Byte; {6 columns, 6 rows}

  PTGame = ^TGame;
  TGame = object
    ... 
  end;

  // TMenu Interface section
  TMenu = object
  private
    p: PTGame;
  public
    Constructor Init(pGame: PTGame);
    Destructor Done;
    Procedure DrawPlayGround;
  end;

// TGame Implementation section
...

// TMenu Implementation section
Constructor TMenu.Init(Var pGame: PTGame);
begin
  p := pGame;
end;

...

Procedure TMenu.DrawPlayGround;
var
  Row, Column: Byte;
begin
  For Row := 1 To MaxRows Do begin
    For Column := 1 To MaxColumns Do
      Write(p^.GetPG[Row, Column]);
    WriteLn;
  end;
end;

// Variable Definition section
Var
  Menu: ^TMenu;
  Game: ^TGame;

// Main Program's Logic section
Begin
  New(Game, Init);
  New(Menu, Init(Game));
    Menu^.DrawPlayGround;
  Dispose(Menu, Done);
  Dispose(Game, Done);
End.

?

[comanche]

Это, конечно, хороший вариант.

Тоеть насколько я понимаю, нельзя два независимых объекта согласовать без вложенности одного в другой?

Возникает второй вопрос: почему вы не выделяли память под P (pGame)? Constructor сам всё выделил?

Немного не понимаю вот этой строки: New(Menu, Init(Game));

Сообщение отредактировано: comanche - 13.03.2006 16:05

[volvo]

Это, конечно, хороший вариант.

"У тети Сони плохого не бывает" (С)

Тоеть насколько я понимаю, нельзя два независимых объекта согласовать без вложенности одного в другой?

Ну, я бы не сказал, что это вложенность, это все-таки p: PTGame, а следовательно указатель на объект типа TGame...

Возникает второй вопрос: почему вы не выделяли память под P (pGame)? Constructor сам всё выделил?

Смотри, что происходит: тип TMenu содержит переменную P... Задача конструктора - выделить в памяти место, достаточное для хранения всех переменных, правда? Зачем я еще что-то должен делать? На то и Constructor ...

Немного не понимаю вот этой строки: New(Menu, Init(Game));

Ну, я же поменял заголовок конструктора, и теперь

Constructor TMenu.Init(pGame: PTGame);

должен получать аргумент - указатель на TGame... Вот я и передаю его при инициализации...

[comanche]

Огромное спасибо и уважуха в квадрате Приятно было сотрудничать

[comanche]

Возник ещё один теоретический вопрос:

Тоесть со статическими объектами нельзя было бы проделывать такие же действия?

[volvo]

Все, что можно с динамикой, можно и со статикой. Операцию "@" еще никто не отменял

[comanche]

А вот такой мы пока ещё не знаем, а если и слышали, то не понимаем её предназначения.

Спасибо!

[comanche]

Эхх мааа... Сделал всё так же как вы сказали, теперь же в результате вывода массива выводятся нули, а если
оставить

New(Menu, Init(Game));
New(Game, Init);
Menu^.DrawPlayGround;
Dispose(Menu, Done);
Dispose(Game, Done);

Т.е. не менять местами

New(Menu, Init(Game));
New(Game, Init);

То выводятся хаотичные значения, причём одни и те же. Help! Help!

Код: (Показать/Скрыть)

Program Ex_5_Prac_SportLoto;
Uses

  CRT, Mouse, ErrCodes;

Const

  MaxColumns = 6;
  MaxRows = 6;

// Type section

Type

  PTGame = ^TGame;
  TPlayGround = Array [1..MaxRows, 1..MaxColumns] OF Byte; {6 columns, 6 rows}

// TGame Interface section

  TGame = object
  private
    PG: TPlayGround;
  public
    Constructor Init;
    Destructor Done;
    Procedure RandomFillPG;
    Procedure UserFillPG;
    Function GetPG: TPlayGround;
  end;

// TMenu Interface section

  TMenu = object
  private
    P: PTGame;
  public
    Constructor Init(var PGame: PTGame);
    Destructor Done;
    Procedure DrawPlayGround;
  end;

// TGame Implementation section

  Constructor TGame.Init;
    begin
      Randomize;
    end;

  Destructor TGame.Done;
    begin
    end;

  Procedure TGame.RandomFillPG;
    var
      Row, Column: Byte;
      i: Byte;
    begin
      i := 0;
      For Row := 1 To MaxRows Do
        For Column := 1 To MaxColumns Do
          begin
            inc(i);
            PG[Row, Column] := i;
          end;
    end;

  Procedure TGame.UserFillPG;
    begin
    end;

  Function TGame.GetPG;
    begin
      GetPG := PG;
    end;

// TMenu Implementation section

  Constructor TMenu.Init;
    begin
      P := PGame;
    end;

  Destructor TMenu.Done;
    begin
    end;

  Procedure TMenu.DrawPlayGround;
    var
      Row, Column: Byte;
    begin
      For Row := 1 To MaxRows Do
        begin
          For Column := 1 To MaxColumns Do
            Write(P^.GetPG[Row, Column]:3);
          WriteLn;
        end;
    end;

// Variable Definition section

Var

  Menu: ^TMenu;
  Game: ^TGame;

// Main Program's Logic section

Begin

  New(Game, Init);
  New(Menu, Init(Game));
    Menu^.DrawPlayGround;
  Dispose(Menu, Done);
  Dispose(Game, Done);
  ReadKey;

End.

[volvo]

Если не менять местами - будет непонятно что, потому что СНАЧАЛА надо инициализировать Game, а потом передавать его в Menu...

Сейчас гляну, что там происходит...
(только я проверяю в FPC, у меня TMT не установлен...)

  Constructor TGame.Init;
    begin
      Randomize;
      RandomFillPG; { Добавь эту строку }
    end;

Попробуй изменить ТОЛЬКО это, у меня выдает то, что было инициализировано:

1 2 3 4 5 6
7 8 9 10 11 12
13 14 15 16 17 18
19 20 21 22 23 24
25 26 27 28 29 30
31 32 33 34 35 36

[comanche]

Да, заработало. В чём же причина?

[volvo]

В том, что просто сделать Randomize недостаточно... Нужно еще и заполнить матрицу значениями. А для этого достаточно сказать компилятору, какая процедура этим занимается... Что я и сделал

[comanche]

Победили!