Движение предмета, С использованием ООП Опции

[Dmi3_j]

Изучаю по книжке ООП, программа должна двигать точку, а она ее просто отображает:

Код

Uses Graph, CRT;

Type
GraphObj = object
     X,Y: Integer;
   Color: Word;
Constructor Init(aX,aY:Integer;AColor:Word);
Procedure Draw(aColor:Word); Virtual;
Procedure Show;
Procedure Hide;
Procedure Move(dX,dY:Integer);
end;
Constructor GraphObj.Init;
begin
X:=aX;
Y:=aY;
end;
Procedure GraphObj.Draw;
begin
end;
Procedure GraphObj.Show;
begin
Draw(Color);
end;
Procedure GraphObj.Hide;
begin
Draw(GetBkColor);
end;
Procedure GraphObj.Move;
begin
Hide;
X:=X+dX;
Y:=Y+dY;
Show
end;

Type
Point = object(GraphObj)

Procedure Draw(aColor:Word); Virtual;
end;

Procedure Point.Draw;
begin
PutPixel(520,290,white);
end;
Var
d,r,q:Integer;
    ln:Line;
begin
  D:=Detect;
  InitGraph(d,r,'');
  Ln.Init(200,200,white);
  Ln.Draw(red);
Repeat
  ln.Move(-10,10);
Until
q>100;
End.

[klem4]

Во первых, стнанная у тебя основная чать, начальное значение q не известно и в цикле repeat оно не меняется, хотя цил по этой переменой +

Procedure Point.Draw;
begin
PutPixel(520,290,white);
end;

У тебя же постоянно получается что точка выводится в одном и том-же месте ...

Сообщение отредактировано: klem4 - 22.01.2006 12:16

[volvo]

А чему у тебя равно Q в начале работы программы? Да и вот так лучше будет:

Procedure Point.Draw;
begin
  PutPixel(X, Y, Color);
end;

Это во-первых...

Во-вторых, и самое главное, ты забыл определить конструктор для Point, а ведь этот объект содержит виртуальные методы, так что конструктор ему просто необходим для инициализации VMT...

И что такое за тип Line?
Ты уж если приводишь исходник, то приводи полностью... То, что бы привел - даже не скомпилируется, не говоря уже о правильной работе...

[Dmi3_j]

Код

{.......}
Point = object(GraphObj)
Constructor Init(aX,aY:Integer;aColor:Word);
Procedure Draw(aColor:Word); Virtual;
end;
Constructor Point.Init;
begin
Inherited Init(aX,aY,aColor);
X:=aX;
Y:=aY;
end;
Procedure Point.Draw;
begin
PutPixel(X,Y,Color);
end;
Var
d,r,q:Integer;
    Pt:Point;
begin
  D:=Detect;
  InitGraph(d,r,'');
  q:=1;
  Pt.Init(200,200,red);
  Pt.Draw(red);
Repeat
  Pt.Move(-10,10);q:=q+1;Delay(100);
Until
q>100;
End.

Точка не отображается.

Сообщение отредактировано: Dmi3_j - 22.01.2006 13:10

[volvo]

Не знаю, как у тебя, у меня вот так все прекрасно отображается:

Uses Graph, CRT;

Type
  GraphObj = object
    X,Y: Integer;
    Color: Word;

    Constructor Init(aX,aY:Integer;AColor:Word);

    Procedure Draw(aColor: Word); virtual;
    Procedure Show;
    Procedure Hide;
    Procedure Move(dX,dY:Integer);
  end;

Constructor GraphObj.Init;
begin
  X:=aX; Y:=aY; Color := AColor;
end;

Procedure GraphObj.Draw;
begin
  PutPixel(X,Y, aColor);
end;

Procedure GraphObj.Show;
begin
  Draw(Color);
end;

Procedure GraphObj.Hide;
begin
  Draw(GetBkColor);
end;

Procedure GraphObj.Move;
begin
  Hide;
  X:=X+dX; Y:=Y+dY;
  Show
end;

type
  Point = object(GraphObj)
    Constructor Init(aX,aY:Integer;aColor:Word);
    Procedure Draw(aColor:Word); Virtual;
  end;

Constructor Point.Init;
begin
  Inherited Init(aX,aY,aColor);
end;
Procedure Point.Draw;
begin
  PutPixel(X,Y,aColor);
end;

Var
  d,r,q:Integer;
  errcode: integer;
  Pt:Point;
begin
  D:=Detect;
  InitGraph(d,r,'');
  errcode := graphresult;
  if errcode <> grok then begin
    writeln('error: ', grapherrormsg(errcode));
    halt(100)
  end;

  q:=1;
  setcolor(white);
  rectangle(10, 10, getmaxx-10, getmaxy-10);

  Pt.Init(200,200,lightred);
  Pt.Show;
  readln;
  Repeat

    Pt.Move(-1, 1);
    q:=q+1;
    Delay( 4500);

  Until q>100;
  closegraph;
End.

Я добавил рамку, чтобы ты видел, инициализировался у тебя вообще граф. режим, или нет, и чтобы удобнее было следить за точкой - она начинает двигаться только после того, как нажмешь на Enter...

Сам сдвиг я тоже уменьшил, т.к. при сдвиге -10 у тебя после 20-го шага точка уже за пределами экрана...

[Dmi3_j]

Спасибо огромное!!!!!!!!

Сообщение отредактировано: Dmi3_j - 22.01.2006 14:20