Графика, Построить n-угольник и произвести с ним следующие манипуляции Опции

[$rvr4vr]

Построить n-угольник и произвести с ним следующие манипуляции:
А. Повернуть на x° по часовой стрелке.
В. Масштабировать рисунок в 2, 4, 6, 8 раз.

[volvo]

Копай в сторону полярной системы координат... Если работать в ней, то первое задание решается банальным увеличением/уменьшением угла для каждой точки, а второе - умножением расстояния от центра на масштаб...

(поиск по форуму может кое-чем помочь, я делал несколько программ, использующих полярную СК)

[$rvr4vr]

не могу врубится как это на мой случай распространить?

[volvo]

То есть? Что непонятно? Как именно "создать" N-угольник? Очень просто, центр экрана принимаешь за центр полярной СК, тогда координаты вершин N-угольника будут соответствовать точкам с удалением R (радиус описанной возле многоугольника окружности) от центра, углы - от 0 до 360 с шагом 360/N ... Запоминаешь эти координаты в массив, например:

Var
  coords: array[1 .. n] of record
    R: integer;
    phi: real;
  end;

Как отобразить многоугольник? Там, где ты читал про "Строфоиду" есть функция put_polar, так вот почти так же, только надо сначала сделать MoveTo в первую точку многоугольника, а потом LineTo в последующие...

Насчет масштабирования и повороты я уже написал выше, что надо делать (для каждой точки)...

Что еще непонятно?

[$rvr4vr]

то есть за начальную точку возьмем точку на К выше центра потом по окружности расставим точки на углах равные 360/n? верно? тогда центр это (getmaxx div 2) и (getmaxy div 2)? а как будет выглядеть формула поворота курсора на 360/N градусов относительно предыдущей точки и ценра?(извини я может туплю и не догоняю элементарного но я просто запарился с этой сессией уже)

[volvo]

Вот так:

uses graph;

const
  n = 5;
  grads = 20;
type
  polar_pnt = record
    r: integer;
    phi: real;
  end;

var
  grDriver, grMode, ErrCode: Integer;
  center_x, center_y: integer;
  coord: array[1 .. n] of polar_pnt;
  pnt: PointType;

procedure convert(p: polar_pnt; var decart: PointType);
begin
  with p do begin
    decart.X := center_x + trunc(r * cos(phi));
    decart.Y := center_y - trunc(r * sin(phi));
  end;
end;

procedure show;
var
  i: integer;
  pnt: PointType;
begin
  for i := 1 to n do begin

    convert(coord[i], pnt);
    if i = 1 then moveto(pnt.X, pnt.Y)
    else lineto(pnt.X, pnt.Y);

    if i = n then begin
      convert(coord[1], pnt);
      lineto(pnt.X, pnt.Y);
    end

  end;
  readln;
  cleardevice;
end;

var i: integer;

begin
  grDriver := Detect;
  InitGraph(grDriver, grMode, '');
  ErrCode := GraphResult;
  if ErrCode <> grOk then begin
    Writeln('Graphics error:', GraphErrorMsg(ErrCode)); halt(100)
  end;

  center_x := getmaxx div 2; center_y := getmaxy div 2;
  for i := 1 to n do
    with coord[i] do begin
      r := 50;
      phi := pred(i) * (2 * Pi / n)
    end;
  show;

  { Увеличиваем масштаб в 2 раза }
  for i := 1 to n do
    coord[i].r := coord[i].r * 2;
  show;

  { Поворачиваем на угол 20 град. ПО часовой стрелке (угол полярной СК уменьшается) }
  for i := 1 to n do begin
    coord[i].phi := coord[i].phi - (grads * Pi / 180);
    if coord[i].phi < 0 then coord[i].phi := coord[i].phi + 2 * Pi;
  end;
  show;

  closegraph;

end.

(не забывай, что вся работа с тригонометрией - через углы в радианах, поэтому присутствует Pi)

[Гость]

volvo, большое спасибо Вам за то что выложили реализацию задачи.