IPB
ЛогинПароль:

> Прочтите прежде чем задавать вопрос!

1. Заголовок темы должен быть информативным. В противном случае тема удаляется ...
2. Все тексты программ должны помещаться в теги [code=pas] ... [/code].
3. Прежде чем задавать вопрос, см. "FAQ", если там не нашли ответа, воспользуйтесь ПОИСКОМ, возможно такую задачу уже решали!
4. Не предлагайте свои решения на других языках, кроме Паскаля (исключение - только с согласия модератора).
5. НЕ используйте форум для личного общения, все что не относится к обсуждению темы - на PM!
6. Одна тема - один вопрос (задача)
7. Проверяйте программы перед тем, как разместить их на форуме!!!
8. Спрашивайте и отвечайте четко и по существу!!!

 
 Ответить  Открыть новую тему 
> Списки, HELP!!!!
vi-rus
сообщение 6.06.2007 20:55
Сообщение #1


Новичок
*

Группа: Пользователи
Сообщений: 23
Пол: Мужской

Репутация: -  0  +


Составить программу, которая вставляет в список L за первым вхождением элемента Е все элементы списка L1, если Е входит в L.
Volvo, дай ПОЖАЛУЙСТА ссылку ,не могу найти
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
volvo
сообщение 6.06.2007 21:14
Сообщение #2


Гость






Я тоже не смог найти пока... Тогда так:

как искать элемент в списке - написано в FAQ, тогда вся твоя программа сведется вот к этому:

var p, found: plist;
...
found := search(L, E);
if found <> nil then begin

  p := L1;
  while p^.next <> nil do p := p^.next;
  p^.next := found^.next;
  found^.next := L1;

end;
 К началу страницы 
+ Ответить 
vi-rus
сообщение 6.06.2007 23:54
Сообщение #3


Новичок
*

Группа: Пользователи
Сообщений: 23
Пол: Мужской

Репутация: -  0  +


Пробовал сделать , но не работает . Помогите ПОЖАЛУЙСТА, мне уже сегодня нужно сдать эту работу


program task3;
uses
    crt;
type
pl = ^list;
str = string[7];

list = record
    field : str;
    next : pl;
end;



var
e:str;
q,p,found,first,l,l1:pl;
procedure search;
begin
l:=first;
while (l<>nil) do if l^.field = e then  q:=l else l:=l^.next;
end;


begin
highvideo;
clrscr;
{}
new(l);
first := nil;
l := first;
{INPUT}
writeln('Type ( if u want to finish type END)');
readln(l^.field);
repeat
      new(l^.next);
      l := l^.next;
      readln(l^.field);
until l^.field = 'END';

l := nil;
l := first;
new(l1);
writeln('Type l1 ( if u want to finish type END)');
readln(l1^.field);
repeat
      new(l1^.next);
      l1 := l1^.next;
      readln(l1^.field);
until l1^.field = 'END';

l1 := nil;
l1 := first;

 writeln('Type e-element');
 readln(e);


{OUTPUT}
l^.next := first^.next;
l1^.next:=first^.next;

search;
found:=q;
if found<>nil then begin
  p:=l1;
  while (p^.next<>nil) do p:=p^.next;
  p^.next:=found^.next;
  found^.next:=l1;
  end;

while (found<>nil) do  begin
        writeln(found^.field);
         found := found^.next^.next;
         end;
readln;
writeln('Press any key.');
readkey;
end.


 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
volvo
сообщение 7.06.2007 0:15
Сообщение #4


Гость






blink.gif Что это ты сделал? На 2 списка - один указатель? Нельзя так... Вот, посмотри, по-моему работает:

program task3;
uses
    crt;
type
  pl = ^list;
  str = string[7];

  list = record
    field : str;
    next : pl;
  end;


function search(first: pl; X: str): pl;
var p: pl;
begin
  search := nil;
  p := first;
  while (p <> nil) do
    if p^.field = X then begin
      search := p; exit;
    end
    else p := p^.next;
end;

procedure add_element(var first, last: pl; X: str);
var p: pl;
begin
  new(p);
  p^.next := nil;
  p^.field := X;

  if first = nil then first := p
  else last^.next := p;

  last := p;
end;


var
  first_L, last_L: pl;
  first_L1, last_L1: pl;

  found, p: pl;
  s: str;
begin
  highvideo;
  clrscr;

  {}
  first_L := nil; last_L := nil;
  writeln('Type ( if u want to finish type END)');
  repeat
    readln(s);
    if s <> 'END' then add_element(first_L, last_L, s)
  until s = 'END';

  first_L1 := nil; last_L1 := nil;
  writeln('Type l1 ( if u want to finish type END)');
  repeat
    readln(s);
    if s <> 'END' then add_element(first_L1, last_L1, s);
  until s = 'END';

  writeln('Type e-element');
  readln(s);

  {OUTPUT}
  found := search(first_L, s);
  if found <> nil then begin
    p := first_L1;
    while p^.next <> nil do p := p^.next;
    p^.next := found^.next;
    found^.next := first_L1;
  end;

  p := first_L;
  while p <> nil do begin
    writeln(p^.field);
    p := p^.next;
  end;
  writeln('Press any key.');
  readln;
end.

 К началу страницы 
+ Ответить 
vi-rus
сообщение 7.06.2007 0:23
Сообщение #5


Новичок
*

Группа: Пользователи
Сообщений: 23
Пол: Мужской

Репутация: -  0  +


БОЛЬШОЕ СПАСИБО тебе, VOLVO. good.gif
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 

 Ответить  Открыть новую тему 
1 чел. читают эту тему (гостей: 1, скрытых пользователей: 0)
Пользователей: 0

 

- Текстовая версия 26.07.2025 9:45
Хостинг предоставлен компанией "Веб Сервис Центр" при поддержке компании "ДокЛаб"