Задачи на знание ООП, (только для Турбо-Паскаля 7.0) Опции

[volvo]

Приветствую всех, зашедших в эту тему...

Такая мысль у меня зрела давно, но вот сегодня (по мотивам одного из топиков в разделе Дельфи) я все-таки решил ее материализовать... Если понравится - продолжу

Тема создана для того, чтобы помочь начинающим программировать обратить внимание на особенности ООП, которые при написании программы и (казалось бы) "неправильной" ее работе могут вызвать недоумение.

Говорю сразу, сложных задач здесь выкладывать не буду, будут простые задачки с подвохом ( или без, это уже на мое усмотрение ), поэтому огромная просьба: НЕ запускайте компилятор... Внимательно посмотрите на код, и попробуйте определить, что будет выведено на экран при его выполнении... Объяснения, почему Вам кажется, что будет именно так, только присветствуются. Но скрывайте посты тегом [SPОILER], чтобы своим ответом не сбивать остальных

Значит, задача №1:

type
  TA = object
    constructor init;

    procedure print; virtual;
  end;

  TB = object(TA)
    constructor init;

    procedure print; virtual;
  end;

constructor TA.init;
begin
  writeln('TA.init');
end;
procedure TA.print;
begin
  writeln('TA type object');
end;

constructor TB.init;
begin
  inherited Init;
  writeln('TB.init');
end;
procedure TB.print;
begin
  writeln('TB type object');
end;

procedure print(X: TA);
begin
  X.print;
end;
procedure print_const(const X: TA);
begin
  X.print;
end;
procedure print_var(var X: TA);
begin
  X.print;
end;

var obj: TB;
begin
  obj.init;
  print(obj);
  print_const(obj);
  print_var(obj);
end.

Запускаем, и на экране появляется...

[hiv]

Можно и усложнить ;)
добавив:

type PTA=^TA;

procedure print_ptr(X: PTA);
begin
  X^.print;
end;

[klem4]

Вот мое предположение:

Спойлер (Показать/Скрыть)

TA.Init
TB.Init
TA type object
TB type object
TB type object

Пойду проверять

[мисс_граффити]

ИМХО:

Спойлер (Показать/Скрыть)

Вызываем TB.init, а он по inherited (до того, как выполнится сам) обращается к TA.init
получаем 2 строчки:
TA.Init
TB.Init
Параметр, передаваемый по значению - по сути есть копия объекта-аргумента, то есть будет содержать только ТА-шную информацию. И методы ТА-шные.
TA type object
TA type object
А тут передаем по адресу... Приведение типов не осуществляется, то есть работаем с ТВ. Ну и метод ТВ-шный.
TB type object

volvo, насчет "понравится ли" - какие могут быть сомнения?
только в той темке, которая про Делфи, вопрос не закрытый какой-то...

Сообщение отредактировано: мисс_граффити - 23.11.2006 15:40

[klem4]

Спойлер (Показать/Скрыть)

Вот и я рассуждал так же как и мисс_граффити, но ошибся в одном месте, по поводу:

procedure print_var(var X: TA);
begin
  X.print;
end;

Тут ведь тоже по адресу параметр передается ! Но почему-то выводится TA-шный метод ...

[volvo]

Андрей, внимательнее... Ты не там ошибся

[klem4]

Ну да это я перепутал мальца, но смысл то остается тотже

Спойлер (Показать/Скрыть)

в подпрограмму объект передается по адресу в print_const(obj);... И по идее в этом случае должен использваоться метод TB. Почему это не так понять опка не могу ...

[volvo]

Так... Хорошо. Тогда еще одна...

Задача №2:
Что можете сказать по поводу этого кода? Любые комментарии (без компилирования и запуска) приветствуются...

type
  PT = ^T;
  T = object
  end;

  PTint = ^Tint;
  Tint = object(T)
    value: integer;

    procedure init(X: integer);
    procedure print;
  end;

  PTfloat = ^Tfloat;
  Tfloat = object(T)
    value: double;

    procedure init(X: double);
    procedure print;
  end;

procedure Tint.init(X: integer);
begin value := X end;
procedure Tint.print;
begin write(value:4) end;

procedure Tfloat.init(X: double);
begin value := X end;
procedure Tfloat.print;
begin write(value:8:4) end;

const
  maxSize = 100;
type
  TArr = object
    arr: array[1 .. maxSize] of PT;

    constructor init;
    procedure set_index(i: integer; p: PT);

    procedure count_each(var p: PT);
  end;

constructor TArr.init;
begin end;
procedure TArr.set_index(i: integer; p: PT);
begin if i <= maxSize then arr[i] := p; end;

procedure TArr.count_each(var p: PT);
var i, count: integer;
begin
  count := 0;
  for i := 1 to maxSize do
    if typeof(arr[i]^) = typeof(p^) then inc(count);
  writeln('count = ', count);
end;


var
  obj_int: ^Tint;
  obj_float: ^Tfloat;
  any_arr: TArr;
begin
  any_arr.init;
  obj_int := new(PTint); obj_int^.value := 3;
  any_arr.set_index(1, obj_int);
  obj_float := new(PTfloat); obj_float^.value := 3.5;
  any_arr.set_index(2, obj_float);
end.

[Bokul]

Классная тема!

Что можете сказать по поводу этого кода?

Т.е. что выведет процедура TArr.count_each(var p: PT) если ее вставить перед последним end'ом?

[volvo]

Что выведет, например,

any_arr.count_each(new(PTfloat));

, если это вставить перед последним end-ом? В частности, что ВООБЩЕ делает эта процедура count_each?

[Bokul]

В частности, что ВООБЩЕ делает эта процедура count_each?

Она считает количество элементов в массиве any_arr.arr у которых тип такой как и у передаваемого аргумента. Хотя с типом аргумента не уверен, так как вместо указателя на объект-родитель ты даешь указатель на объект-наследник.
Вопрос: считать, что при вызове проги все элементы этого массива равны nill?

Спойлер (Показать/Скрыть)

Мне кажется должна возникнуть ошибка, так как ты инициализировал объекты не использую конструкторов, а значит теблица VMT не созданна, а значит typeof объекта без VMT вызовет ошибку:

Can only be applied to object types that have a VMT; all other types result in an error

Сообщение отредактировано: Bokul - 25.11.2006 1:03

[Bokul]

В общем не выдержал я решил попробовать скомпилировать (не запуская) код.
Компилятору не понравилось две строчки:
1-ая

procedure Tfloat.init(X: double);
begin value := X end; {Must be in 8087 mode to compile this}

Я поставил директиву {$N+}, помогло.

2-ая

procedure TArr.count_each(var p: PT);
var i, count: integer;
begin
  count := 0;
  for i := 1 to maxSize do
    if typeof(arr[i]^) = typeof(p^)  then {Object type expected}
        inc(count);
  writeln('count = ', count);
end;

Тут я не понимаю в чем проблема...

volvo у тебя все нормально компилировалось?

[volvo]

А я предупреждал:

будут простые задачки с подвохом ( или без, это уже на мое усмотрение )

Здесь как раз и было интересно, будет ли кто-то смотреть на код, и пробовать его анализировать, или код будет скопирован, и Atl+F9... Нет. Этот код не должен компилироваться. Следующим моим вопросом должен был быть вопрос "А как, собственно, заставить эту программу компилироваться", но...

В-общем, я так понимаю, что это никому не интересно кроме Bokul-а, ну что-ж... Дело ваше... Складывать числа, табулировать вывод данных и в тысячный раз делать процедуру сортировки "пузырьком" как видно, интереснее... Тему открепляю, пускай уходит вниз... Искусственно поддерживать "живучесть" я не намерен...

[мисс_граффити]

и мне интересно.
просто в тысячный раз скинуть пузырек можно и между делом, а здесь надо посидеть подумать.
*эт я пытаюсь себя заставить зачетную работу по философии делать.... уже забила.
volvo, следующий вопрос должен был быть "как заставить компилироваться" или "как заставить выдать определенный результат, имеющий какое-то значение"?
компилироваться, думаю, будет вот так:
({$N+} не вставляла как не относящееся к названной теме)

type
  PT = ^T;
  T = object
  {
    добавляем конструктор в родительский класс - остальные пусть наследуют...
    при желании можно было просто переделать init....
  }
  constructor create; 
  end;

  PTint = ^Tint;
  Tint = object(T)
    value: integer;
    procedure init(X: integer);
    procedure print;
  end;

  PTfloat = ^Tfloat;
  Tfloat = object(T)
    value: double;
    procedure init(X: double);
    procedure print;
  end;

procedure Tint.init(X: integer);
begin value := X end;
procedure Tint.print;
begin write(value:4) end;

procedure Tfloat.init(X: double);
begin value := X end;
procedure Tfloat.print;
begin write(value:8:4) end;

const
  maxSize = 100;
type
  TArr = object
    arr: array[1 .. maxSize] of PT;

    constructor init;
    procedure set_index(i: integer; p: PT);

    procedure count_each(p: PT); {убираем var... почему - см.ответ на предыдущий вопрос}
  end;

constructor TArr.init;
begin end;
procedure TArr.set_index(i: integer; p: PT);
begin if i <= maxSize then arr[i] := p; end;

procedure TArr.count_each(p: PT);
var i, count: integer;
begin
  count := 0;
  for i := 1 to maxSize do
    if typeof(arr[i]^) = typeof(p^) then inc(count);
  writeln('count = ', count);
end;

constructor T.Create;
begin end;

var
  obj_int: ^Tint;
  obj_float: ^Tfloat;
  any_arr: TArr;
begin
  any_arr.init;
  obj_int := new(PTint);
  obj_int^.Create; 
  obj_int^.value := 3;
  any_arr.set_index(1, obj_int);
  obj_float := new(PTfloat);
  obj_float^.create; 
  obj_float^.value := 3.5;
  any_arr.set_index(2, obj_float);
  any_arr.count_each(new(PTfloat));
end.

[Bokul]

    
obj_int := new(PTint);
obj_int^.Create;

Можно заменить на

  obj_int := new(PTint,Create);

Значит я был прав насчет VMT таблицы? Выходит что компилятор сам может "вылавить" такую ошибку?

Сообщение отредактировано: Bokul - 26.11.2006 0:23

[volvo]

Выходит что компилятор сам может "вылавить" такую ошибку?

Не совсем... Компилятор делает медвежью услугу... С одной стороны, он контролирует в Compile-Time, что у типа, к которому применяется TypeOf, вообще НЕ МОЖЕТ быть VMT, следовательно, он не может использовать TypeOf, а с другой...

Берем код мисс_граффити... Вопрос на засыпку: будет работать корректно, или нет? Если ДА - то что будет напечатано, если НЕТ - где будет сбой...

[Bokul]

procedure count_each(p: PT); {убираем var... почему - см.ответ на предыдущий вопрос}

А это имеет значения в данном случае? Мне кажется что нет, мы же передаем не объект, а указатель на него, а значит нам все-равно будет ли он копироваться или нет. ИМХО.

[volvo]

передаем не объект, а указатель на него, а значит нам все-равно будет ли он копироваться или нет

Ага... Только вот не скомпилируется у тебя с Var программа, а без Var или с Const - это будет компилироваться... Объяснить, почему?

[Bokul]

Ага... Только вот не скомпилируется у тебя с Var программа, а без Var или с Const - это будет компилироваться...

А я уже ответ хотел писать опираясь на это...

Объяснить, почему?

Да.

[volvo]

Потому, что при описании

procedure count_each(Var p: PT);

компилятор ждет передачи адреса переменной, которую можно менять, то есть, не просто адреса чего-то там в памяти, а именно адрес переменной... А вот Const означает, что можно передать любой адрес, изменять-то по нему ничего нельзя, тем более - вообще БЕЗ спецификатора, можно передавать как адрес переменной, так и просто адрес, он все равно скопируется в стек, и никаких действий с объектом, на который он указывает, производиться не будет...

А теперь смотрим, КАК вызывается count_each:

any_arr.count_each(new(PTfloat));

Что передается? Адрес... Переменной-то нет... Так что с Var-ом нельзя... Внимательнее смотри не только на объявление процедуры, но и на вызов...