Найти выражение в строке и подсчитать. Опции

[Mis]

Подскажите пожалуйста, второй день не могу решить

Вычислить результат выражения, заданного символьным набором abc22+4cd+32.5ef, выделив из набора символов 22 + 4 + 32.5.

На данный момент есть вот это:

Код

uses crt;
const number=['1','2','3','4','5','6','7','8','9','0'];
      plus=['+'];

var
s,a: string;
i,k,rezult,c1,code:integer;

begin
clrscr();
writeln('Введите строку=');
readln(s);

i:=1;
k:=1;
c1:=0;
rezult:=0;

while k<=length(s) do
  begin
  
    a:='';
    c1:=0;

    while not(s[i] in number) do
       i:=i+1;
  
    while s[i] in number do
      begin
        a:=a+s[i];
        i:=i+1;
      end;
    val(a,c1,code);
  
   if s[i] in plus then rezult:=rezult+c1;

   k:=k+1;
end;

writeln('Результат=',rezult);
end.

Но работать корректно оно не хочет

[IUnknown]

А зачем? Есть у тебя строка, содержащая буквы, цифры и знаки, ты хочешь из нее буквы убрать, и вычислить значение полученного выражения. По какому праву убрал буквы, спрашивается?

Не, оно, конечно, решаемое... (Показать/Скрыть)

Как-то вот так, набирал без компилятора, так что может быть придется подправить что-нибудь:

const
   number = ['0' .. '9'];
   plus = ['+'];

var
   value : real;
   rezult : real;
   i, err : integer;
   sign : char;

   s, a : string;
begin
   writeln('Введите строку: ');
   readln(s);

   i := 1;
   a := '';
   sign := '+';
   while i <= length(s) do
   begin
      while (i <= length(s)) and (not (s[i] in plus)) do
      begin
         if s[i] in number + ['.'] then a := a + s[i];
         inc(i);
      end;
      val(a, value, err); a := '';
      if err <> 0 then value := 0;

      if (i > length(s)) or (s[i] in plus) then
      begin
         case sign of { Это для возможности добавить еще и "минус" }
            '+' : rezult := rezult + value;
         end;
         sign := s[i];
         inc(i);
      end;
   end;
   writeln('result = ', rezult:10:5);
end.

, но смысла я в этом по-прежнему не вижу... Возможно, будет проще удалить из строки все "неправильные" символы, и работать только с оставшимися, пробуй.

[Mis]

Спасибо большое! Сейчас буду пытаться понять как все это работает.

[Mis]

Я прошу прощения, паскаль я только начал изучать. Не могу понять принцип работы вот этого условия:

Код

  if s[i] in number + ['.']

Не могли бы вы пояснить как работает тут знак +?

[IUnknown]

Здесь "+" это объединение множеств (результат - все символы, которые содержатся или в первом, или во втором множестве, не путай с "*", которое означает "верни все элементы, одновременно присутствующие в первом и втором множествах").

То есть, number содержит все цифры от "0" до "9", а потом этим самым плюсом к цифрам добавляется еще и точка. По-другому можно было бы записать так:

if s[ i ] in ['0' .. '9', '.'] then ...

именно это и делает приведенный выше код.

Сообщение отредактировано: IUnknown - 22.06.2011 20:21

[Mis]

Огромное спасибо за разъяснение!