Цифры числа в том же порядке Опции

[Ozzя]

Студентка одна попросила о помощи. Задача

ДАНО нат. число. Поместить его цифры в массив в том же порядке, в каком они были записаны.

Склеил из форумовских

program forforum;
var
  a, b  : LongInt;
  q     : Array [1..16] of Integer;
  i, n  : Integer;

begin
  readLn(a);
  b:=0;
  while a<>0 do
    begin
      b:=b*10+a mod 10;
      a:=a div 10;
    end;
  i:=1;
  while b<>0 do
    begin
      n:=i;
      a:= b mod 10;
      b:= b div 10;
      q[i]:=a;
      i:=i+1;
    end;
  for i:=1 to n do
    writeLn(q[i]);
  readln;
end.

Ан нет, преподу не понравилось. Нужно оптимизировать, обойдясь одним циклом. И что-то я тут задумался

Сообщение отредактировано: Ozzя - 10.02.2010 15:50

[Unconnected]

Может, препод это имел в виду?

var a:string;
    m:array[1..16] of byte;
    i:byte;
    code:integer;
begin
  readln(a);
  for i:=1 to length(a) do begin
    val(a[i],m[i],code);
    writeln(m[i]);
  end;
end.

[Ozzя]

Нет. Строки использовать нельзя.

[volvo]

Оззя, ты чего?

program forforum;
var
  a, b  : LongInt;
  q     : Array [1..16] of Integer;
  i, n  : Integer;
begin
  readLn(a);

  i := 0;
  b := 1000000000; n := 10;
  while a > 0 do
  begin
    if b > a then begin
      b := b div 10; dec(n);
    end
    else begin
      q[n - i] := a mod 10; inc(i);
      a := a div 10;
      b := b div 10;
    end;
  end;

  for i := 1 to n do
    writeLn(q[i]);
  readln;
end.

[Ozzя]

 while a > 0 do
  begin
    if b > a then begin
      b := b div 10; dec(n);

Ведь шла мысль в этом направлении...
Блин

Оззя, ты чего?

Я лох
Уволюсь в управдомы

Добавлено через 15 мин.
Вольво, выручай!
Препод поменял
строки

  a, b  : LongInt;
  q     : Array [1..16] of Integer;

на

  a, b  : Int64;
  q     : Array [1..64] of Integer;

ввел 1234567890123456
Программа виснет
И заявил: "Ваш код машинно-зависим. Требуется общее решение".
Оно вообще возможно?

Добавлено через 13 мин.
Что-то типа такого

if sizeof(b)=4 // longint (dword)
then
  b := 1000000000;

if sizeof(b)=8 // int64
then
  b := 1000000000000000000;

не покатит?

[volvo]

Оно вообще возможно?

Возможно, возможно... Все возможно... Блин, времени тестировать как следует нет - погоняй вот это:

program forforum;
uses math;

type
  MyInt = Int64;
var
  a, b  : MyInt;
  q     : Array [1 .. 8 * sizeof(MyInt)] of Integer;
  i, n, start : Integer;
begin
  // readLn(a);
  a := 1234567890123456;
  // a := 45887;

  i := 0;

  n := trunc(log10(High(MyInt)));
  start := n + 1;

  while a > 0 do
  begin
    if n > log10(a) then begin
      dec(n); dec(start);
    end
    else begin
      q[start - i] := a mod 10; inc(i);
      a := a div 10;
      dec(n);
    end;
  end;

  for i := 1 to start do
    writeLn(q[i]);
  readln;
end.

(отмазка со стороны преподавателя, что Log10 нет в Turbo Pascal-е не принимается, ибо во-первых, ее очень просто написать самому, а во-вторых, Int64 там тоже нет...)

[klem4]

вот мой вариант, не знаю на сколько проактит у препода, log10 и power можно заменить как ужы было сказано, + если a = 0, надо отдельную ветку сделать. А так работает

uses math;
var
    a           : Int64;
    i           : integer;
    q           : Array [1..64] of Integer;
begin
    a := 9223372036854775807;
    for i :=trunc( log10(a) ) downto 0 do q[i+1] := (a div trunc( power(10, i) ) mod 10);
    for i := trunc( log10(a) ) + 1 downto 1 do write(q[i]);
end.

ps вариант с минимальным кол-вом переменных, trunc( log10(a) ) можно запомнить при желании.

Сообщение отредактировано: klem4 - 16.02.2010 22:03