Одномерный массив - вроде бы просто? Опции

[Petruxa]

Ребят помогите пожалуйста, второй день голову ломаю, что-то никак не выходит!
Найти три наименьших по значению элемента одномерного массива (равные не учитывать) целых чисел, введеных с клавы. Заменить их на соответствующие им индексы.
Спасибо

[volvo]

Я бы сделал вот это (для общего случая, а не только для трех минимумов):

const
  n = 11;
  m =  3;

type
  arrType = array[1 .. n] of integer;
  minType = array[1 .. m] of integer;

const
  a: arrType = (1, 2, 3, 4, 3, 2, 7, 6, 3, 3, 1);

var
  found: boolean;
  mins: minType;
  i, j, k: integer;

begin
  for i := 1 to m do mins[i] := -1;

  for i := 1 to n do begin

    { Проверяем, было ли это значение уже обработано }
    found := false;
    for j := 1 to m do
      if (mins[j] <> -1) and (a[i] = a[mins[j]]) then found := true;

    { если было - берем следующее }
    if found then continue;

    { а тут, собственно, заполняем массив минимумов }
    j := 1;
    while (j <= m) and (mins[j] <> -1) and (a[mins[j]] < a[i]) do inc(j);
    if j <= m then begin
      for k := m downto j + 1 do mins[k] := mins[k - 1];
      mins[j] := i;
    end;

  end;

  { и меняем индексы }
  for i := 1 to m do
    if mins[i] <> -1 then a[mins[i]] := mins[i];

end.