Задачи на знание ООП, (только для Турбо-Паскаля 7.0) Опции

[volvo]

Приветствую всех, зашедших в эту тему...

Такая мысль у меня зрела давно, но вот сегодня (по мотивам одного из топиков в разделе Дельфи) я все-таки решил ее материализовать... Если понравится - продолжу

Тема создана для того, чтобы помочь начинающим программировать обратить внимание на особенности ООП, которые при написании программы и (казалось бы) "неправильной" ее работе могут вызвать недоумение.

Говорю сразу, сложных задач здесь выкладывать не буду, будут простые задачки с подвохом ( или без, это уже на мое усмотрение ), поэтому огромная просьба: НЕ запускайте компилятор... Внимательно посмотрите на код, и попробуйте определить, что будет выведено на экран при его выполнении... Объяснения, почему Вам кажется, что будет именно так, только присветствуются. Но скрывайте посты тегом [SPОILER], чтобы своим ответом не сбивать остальных

Значит, задача №1:

type
  TA = object
    constructor init;

    procedure print; virtual;
  end;

  TB = object(TA)
    constructor init;

    procedure print; virtual;
  end;

constructor TA.init;
begin
  writeln('TA.init');
end;
procedure TA.print;
begin
  writeln('TA type object');
end;

constructor TB.init;
begin
  inherited Init;
  writeln('TB.init');
end;
procedure TB.print;
begin
  writeln('TB type object');
end;

procedure print(X: TA);
begin
  X.print;
end;
procedure print_const(const X: TA);
begin
  X.print;
end;
procedure print_var(var X: TA);
begin
  X.print;
end;

var obj: TB;
begin
  obj.init;
  print(obj);
  print_const(obj);
  print_var(obj);
end.

Запускаем, и на экране появляется...

[Bokul]

и что я получу, догадайся?

Большую толстую ошибку
Получаем 10 указателей на один и тот же объект, что есть не очень хорошо, так как потом мы попытаемся их все освободить из памяти при помощи виртуального деструктора, но после первого "освобождения", нам останется 9 указателей на объект без VMT, что при последующим вызове виртуального done вызовет ошибку 210.

а проверку, которую я показал делать пользователю класса действительно не совсем корректно, хотя даже это не помогло...

Все понял. Мне вообще интересует вопрос о том, что должен знать и не знать объект.

А дело-то все в том, что TypeOf во время компиляции не может проверить правильность таблиц виртуальных методов

Я тут уже задавал вопрос, но так и не услышал ответа: что на самом деле делает TypeOf? Возвращает значения поля виртуальных объектов у объекта?
А как она может проверить правильность этих таблиц? Ведь вся инфа об объекте хранится именно там?

наличие правильной VMT не гарантируется ничем, кроме вызова конструктора...

Я так и не понял (вернее опять запутался) что делает конструктор. Я думал, что он заполняет ПВМ (поле виртуальных методов), а в построении таблиц он не участвует.

Вопрос Из чего состоит размер объекта? Только из его полей + , при условии существования конструктора, 4 байтов для ПВМ?