Задачи на знание ООП, (только для Турбо-Паскаля 7.0) Опции

[volvo]

Приветствую всех, зашедших в эту тему...

Такая мысль у меня зрела давно, но вот сегодня (по мотивам одного из топиков в разделе Дельфи) я все-таки решил ее материализовать... Если понравится - продолжу

Тема создана для того, чтобы помочь начинающим программировать обратить внимание на особенности ООП, которые при написании программы и (казалось бы) "неправильной" ее работе могут вызвать недоумение.

Говорю сразу, сложных задач здесь выкладывать не буду, будут простые задачки с подвохом ( или без, это уже на мое усмотрение ), поэтому огромная просьба: НЕ запускайте компилятор... Внимательно посмотрите на код, и попробуйте определить, что будет выведено на экран при его выполнении... Объяснения, почему Вам кажется, что будет именно так, только присветствуются. Но скрывайте посты тегом [SPОILER], чтобы своим ответом не сбивать остальных

Значит, задача №1:

type
  TA = object
    constructor init;

    procedure print; virtual;
  end;

  TB = object(TA)
    constructor init;

    procedure print; virtual;
  end;

constructor TA.init;
begin
  writeln('TA.init');
end;
procedure TA.print;
begin
  writeln('TA type object');
end;

constructor TB.init;
begin
  inherited Init;
  writeln('TB.init');
end;
procedure TB.print;
begin
  writeln('TB type object');
end;

procedure print(X: TA);
begin
  X.print;
end;
procedure print_const(const X: TA);
begin
  X.print;
end;
procedure print_var(var X: TA);
begin
  X.print;
end;

var obj: TB;
begin
  obj.init;
  print(obj);
  print_const(obj);
  print_var(obj);
end.

Запускаем, и на экране появляется...

[volvo]

Кстати, я нашел у тебя еще кое-что не совсем корректное... Смотри:

function TArr.set_index(const p: PT):boolean;
begin
  inc(num);
  if num<= maxSize then
     begin
         arr[num]:=p;
         set_index:=true;
     end
  else
      begin
          dec(num);
          dispose(p,done);
          set_index:=false;
      end;
end;

- полностью твой код, у меня этого просто не было... А теперь представь, что мне надо первые 10 элементов установить в значение 3.5 - неужели для этого я должен инициализировать переменную 10 раз... Я сделал так:

  obj_float := new(PTfloat,create);
  obj_float^.value := 3.5;
  for i:=1 to 10 do
      begin
        if obj_float <> nil then { <--- Вот эту проверку, кстати, пользователь, делать не должен ... }
           any_arr.set_index(obj_float);
      end;

и что я получу, догадайся?

(а проверку, которую я показал делать пользователю класса действительно не совсем корректно, хотя даже это не помогло...)

При отладки в TP, как можна понять, что это 210-ая,? Она же "фатальная"?

У меня в верхней строке экрана сообщается, какая ошибка произошла, ничего никуда не вылетает...

А существование VMT, гарантирует существование у объекта конструктора, деструктора или хотя бы одного виртуального метода?

Существование VMT гарантируется вызовом конструктора. А наличие деструктора и виртуальных методов (при существовании VMT) - это уже проблема программиста... Они могут быть, а могут не быть - это синтаксисом не оговорено...

С другой стороны, даже наличие у объекта 10 виртуальных методов тебе ничего не даст, если ты НЕ сконструировал экземпляр как положено, т.е. можно сказать так: наличие правильной VMT не гарантируется ничем, кроме вызова конструктора... А дело-то все в том, что TypeOf во время компиляции не может проверить правильность таблиц виртуальных методов, ибо эти самые таблицы только в RunTime создаются...