Задачи на знание ООП, (только для Турбо-Паскаля 7.0) Опции

[volvo]

Приветствую всех, зашедших в эту тему...

Такая мысль у меня зрела давно, но вот сегодня (по мотивам одного из топиков в разделе Дельфи) я все-таки решил ее материализовать... Если понравится - продолжу

Тема создана для того, чтобы помочь начинающим программировать обратить внимание на особенности ООП, которые при написании программы и (казалось бы) "неправильной" ее работе могут вызвать недоумение.

Говорю сразу, сложных задач здесь выкладывать не буду, будут простые задачки с подвохом ( или без, это уже на мое усмотрение ), поэтому огромная просьба: НЕ запускайте компилятор... Внимательно посмотрите на код, и попробуйте определить, что будет выведено на экран при его выполнении... Объяснения, почему Вам кажется, что будет именно так, только присветствуются. Но скрывайте посты тегом [SPОILER], чтобы своим ответом не сбивать остальных

Значит, задача №1:

type
  TA = object
    constructor init;

    procedure print; virtual;
  end;

  TB = object(TA)
    constructor init;

    procedure print; virtual;
  end;

constructor TA.init;
begin
  writeln('TA.init');
end;
procedure TA.print;
begin
  writeln('TA type object');
end;

constructor TB.init;
begin
  inherited Init;
  writeln('TB.init');
end;
procedure TB.print;
begin
  writeln('TB type object');
end;

procedure print(X: TA);
begin
  X.print;
end;
procedure print_const(const X: TA);
begin
  X.print;
end;
procedure print_var(var X: TA);
begin
  X.print;
end;

var obj: TB;
begin
  obj.init;
  print(obj);
  print_const(obj);
  print_var(obj);
end.

Запускаем, и на экране появляется...

[volvo]

А как освободить с памяти объект на который нет указателя?

А вот с этого места, пожалуйста, поподробнее... То есть, ты считаешь, что вот эта программа:

type
  pT = ^T;
  T = object
    value: integer;

    constructor init(x: integer);
    procedure print; virtual;
  end;

constructor T.init(x: integer);
begin value := X; end;
procedure T.print;
begin writeln(value); end;


procedure print_me(const p: pT);
begin
  p^.print;
end;

begin
  print_me(new(pT, init(20)));
  print_me(new(pT, init(30)));
  print_me(new(pT, init(40)));
end.

не напечатает ничего? Как же она может напечатать, если я передаю (да еще и константно) указатель на объект, который НЕ существует? Вынужден тебя огорчить, она будет работать... Объясни тогда, почему, если НЕТ указателя?

Полностью согласен.

Ха... А ты что думал, я дам программку, в которой надо изменить 2 символа и она будет работать, как положено? Нет уж...