простая задача на массив, девушке срочно требуется помощь Опции

[pusha]

помогите, пожалуйста, девушке-блондинке... )) ни разу не работала с массивами, а здесь придется... программа простая сама понимаю.., но вам же не сложно мне помочь и написать вот это: Даны целые числа а1,а2,...,аn, среди которых могут быть повторяющиеся. Составьте новый массив из чисел, взятых по одному из каждой группы равных членов данной последовательности. Очень прошу..., буду благодарна за любую помощь...

[pusha]

ой... еще вопрос: здесь выводятся все члены последовательности без повторений, а как сделать, чтобы выводились только те, которые повторяются, но в единичном экземпляре(без тех, которые не повторяются в первоначальном массиве)?

[Lapp]

как сделать, чтобы выводились только те, которые повторяются, но в единичном экземпляре(без тех, которые не повторяются в первоначальном массиве)?

Если взять за основу код мисс_граффити, то нужно добавить еще один массив, который заполняется примерно так же. Я очень извиняюсь, но я изменил кое-какие названия переменных для большей корреляции с назначением. Так, выходной массив я назвал Dup (Duplication, дубли), а промежуточный - All (все различные элементы). Признак добавления элемента в массив я назвал Take (брать).

{for pusha, by Miss_Graffity & Lapp}
{to delete all singles and duplications from array}
const
  n=10;

var
  a,All,Dup:array[1..n]of integer;
  i,j,k,l,Count:integer;
  Take:boolean;

begin
  k:=0;
  l:=0;
  for i:=1 to n do begin
    a[i]:=random(10);
    write(a[i],' ');
    Take:=true;
    for j:=1 to k do if All[j]=a[i] then Take:=false;
    if Take then begin
      inc(k);
      All[k]:=a[i];
    end
    else begin
      Take:=true;
      for j:=1 to l do if Dup[j]=a[i] then Take:=false;
      if Take then begin
        Inc(l);
        Dup[l]:=a[i]
      end
    end
  end;
  writeln;
  for i:=1 to l do write(Dup[i],' ');
  readln;
end.

Ниже - другой вариант решения. Он основан на множествах, что несет в себе некие преимущества (проще и быстрее), но и недостатки тоже:
- множества не могут содержать более 255 элементов;
- возможно, вы еще просто не проходили множества..

{for pusha by Lapp}
{to delete singles and duplicates, uses sets}
const
  n=20;
  r=20;  {range, must be < 256}

var
  a,b:array[1..n]of integer;
  All,Dup:set of byte;
  i,j:integer;

begin
  for i:=1 to n do a[i]:=Random(r ); {заполняем массив случайными числами}
  All:=[];                          {готовим множество всех элементов}
  Dup:=[];                          {готовим множество для дублей}
  for i:=1 to n do begin
    Write(a[i]:3);
    if a[i] in All then Dup:=Dup+[a[i]]; {заполняем множество дублей}
    All:=All+[a[i]]                 {заполняем множество всех}
  end;
  WriteLn;
  j:=0;                             {готовим счетчик выходного массива}
  for i:=1 to n do if a[i] in Dup then begin
    Inc(j);                         {увеличиваем счетчик выходного массива}
    b[j]:=a[i];                     {заполняем выходной массив}
    Dup:=Dup-[a[i]]                 {убираем элемент из множества дублей}
  end;
  for i:=1 to j do Write(b[i]:3);
  WriteLn;
  ReadLn
end.

PS
не вижу доказательств в профиле, что ты блондинка..