Извлечения корня квадратного, Задача на целые числа Опции

[barlog]

Нужно было составить программу демонстрирующая извлечения корня квадратного.
Дошёл до такого вот момента

Uses Crt;
Var x,b,z,l,c,r,d,i,u,um:Longint;
    k:byte; s:string;
Begin
 ClrScr;
{------------------------------------------------------}
 TextColor(white);
 GotoXY(15,1); WriteLn('Izvlechenia korna kvadratnogo');
 WriteLn('Vvedite chislo');
 WriteLn('      ЪДДДДДДДД');
 Write('     \і'); ReadLn(x);
 GotoXY(15,4);Write('=');
{------------------------------------------------------}
 for k:=2 to 5 do
  begin
   GotoXY(6,3*k);Write('ДДДДДДДДДДД');
  end;
{------------------------------------------------------}
 str(x,s);
 l:=round(length(s)/2)-1;
 b:=x; z:=1; r:=0;
{------------------------------------------------------}
 while b>=100 do
  begin
   b:=b div 100;
   z:=z*100
  end;
{------------------------------------------------------}
 c:=9;
 while c*c>b do c:=c-1;
 r:=r*10+c;
 d:=c*c;
 x:=x-d*z;   {x=3654321}
 ReadKey; GotoXY(8,5); Write(d);
 ReadKey; GotoXY(16,4); Write©;
{------------------------------------------------------}
 l:=l-1;         {l=2}
 z:=z div 100;   {z=10000}
 b:=x;            {b=3654321}
 for i:=1 to l do b:=b div 100;    {b=365}
 ReadKey; GotoXY(8,7); Write(b);
 c:=9;
 while (20*r+c)*c>b do c:=c-1;      {c=7}
 r:=r*10+c;                        {r=27}
 u:=r*2-c;                          {u=47}
 um:=u*c;                          {um=47*7=329}
 ReadKey; GotoXY(3,7); Write(u);
 ReadKey; GotoXY(4,8); Write©;
 ReadKey; GotoXY(8,8); Write(um);
 ReadKey; GotoXY(17,4); Write©;
{------------------------------------------------------}
 l:=l-1;                          {l=1}
 b:=x;                           {b=3654321}
 b:=b-um*z;                      {b=364321}
 z:=z div 100;                   {z=100}
 for i:=1 to l do b:=b div 100;
 ReadKey; GotoXY(9,10); Write(b); {b=3643}
 c:=9;
 while (20*r+c)*c>b do c:=c-1;
 r:=r*10+c;
 u:=r*2-c;
 um:=u*c;
 ReadKey; GotoXY(3,10); Write(u);
 ReadKey; GotoXY(5,11); Write©;
 ReadKey; GotoXY(9,11); Write(um);  {3276}
 ReadKey; GotoXY(18,4); Write©;
{------------------------------------------------------}
 l:=l-1;            {l=0}
 b:=b*z+x mod 100;
 b:=b-um*z;
 z:= z div 100;
 for i:=1 to l do b:=b div 100;
 ReadKey; GotoXY(10,13); Write(b);
 c:=9;
 while (20*r+c)*c>b do c:=c-1;
 r:=r*10+c;
 u:=r*2-c;
 um:=u*c;
 ReadKey; GotoXY(3,13); Write(u);
 ReadKey; GotoXY(6,14); Write©;
 ReadKey; GotoXY(10,14); Write(um);
 ReadKey; GotoXY(19,4); Write©;
{------------------------------------------------------}
 b:=b-um;
 ReadKey; GotoXY(11,16); Write(b);
 ReadLn;
End.

Немогу загнать всё это в цикл. Ввожу семизначное число 7654321 и над ним эксперементирую.
Другие семи и восьми значные тоже считает, до запятой.
Надо чтобы и по короче числа брал, вместо того чтобы нули писал в конце.
Может где-то перемудрил. Помогите довести до ума пожалуйста!

[volvo]

А ты не можешь зациклить одно, и НЕ зациклить другое... У тебя часть действий повторяется, а вот кое-что каждый раз новое:

Первый проход:

 z:=z div 100;   {z=10000}
 b:=x;            {b=3654321}

Второй проход:

 b:=x;                           {b=3654321}
 b:=b-um*z;                  {b=364321}
 z:=z div 100;                   {z=100}

Третий проход:

 b:=b*z+x mod 100;
 b:=b-um*z;
 z:= z div 100;

Как ты ЭТО хочешь зациклить? Сначала приведи это к виду, когда все переменные на каждой итерации изменяются одинаково, потом зацикливать будешь...

[barlog]

Попробую, тока не забывайте про эту тему пока, хорошо?! Как получиться выложу.

[volvo]

barlog,
вот что получилось у меня (только без всех этих GotoXY, их сам добавь, если нужно... Моя программа просто иллюстрирует процесс получения результата):

{ Эти 2 функции - для удобства, чтобы не вызывать Str/Val напрямую }
function int_to_str(i: longint): string;
var s: string;
begin
  str(i, s);
  int_to_str := s;
end;
function str_to_int(s: string): longint;
var
  i: longint;
  err: integer;
begin
  val(s, i, err);
  str_to_int := i;
end;

var
  s_num, n: longint;
  err: integer;
  before_s, cs, s, ns, res: string;
  p, c: byte;

begin
  write('n = '); readln(n);
  { n := 54321; }
  writeln(n:20);
  str(n, ns);

  res := '';

  p := 1 + byte(not odd(length(ns)));
  s := copy(ns, 1, p);
  delete(ns, 1, p);

  s_num := str_to_int(s);
  c := 1;
  while sqr( c ) <= s_num do inc( c );
  dec( c );
  writeln(s:(20 - length(ns)), c:10);

  res := res + int_to_str( c );
  writeln(sqr( c ):(20 - length(ns)));

  s_num := s_num - sqr( c );
  str(s_num, s);

  repeat
    s := s + copy(ns, 1, 2);
    delete(ns, 1, 2);

    before_s := int_to_str(2 * str_to_int(res));
    c := 0;
    while str_to_int(s) - (10 * str_to_int(before_s) + c) * c >= 0 do inc( c );
    dec( c );

    writeln(before_s:9, c:1, s:(10 - length(ns)), c:10);
    writeln((10 * str_to_int(before_s) + c) * c:(20-length(ns)));

    res := res + int_to_str( c );
    s := int_to_str(str_to_int(s) - (10 * str_to_int(before_s) + c) * c);
  until length(ns) = 0;

  writeln('res = ', res);
end.

Проверялось на 5-ти и 7-ми значных числах... Вроде не сбоит...