Pascal. Работа с текстом. Опции

[InviZible]

Решить задачу на обработку текста, использую функции работы со строками.
Предполагается, что исходным является текстовый файл. В текст могут входить слова из латинских букв, цифры, знаки арифметической операции, точка, запятая, пробел.

Задача: Вывести на экран те слова, которые отличны от последнего слова текста и первая буква этого слова входит в него ещё раз.

больше интересует: как найти последнее слово в строке и из каких символов оно состоит.

Заранее спасибо.

[volvo]

Я ж тебе на Винограде ответил

Ну ладно, смотри:

const
  delimit = [#0..#32,'.',',',':',';','!','?','"','+','-'];
type
  TWords = array[1..40] of string;

var
  words : TWords;

function GetWords(before: byte; s : string; var w : TWords) : byte;
var
  i, back, n, count: byte;
  st: string;
begin
  i := 1;
  n := before;
  while(i<=length(s)) do begin
    while(i<=length(s)) and (s[i] in delimit) do inc(i);
    if i<=length(s) then begin
      back := i;
      while(i<=length(s)) and not(s[i] in delimit) do inc(i);
      st := copy(s, back, i-back);

      inc(n);
      w[n] := st;
    end;
  end;
  GetWords := n;
end;

var
  f: text;
  s: string;
  n, i: integer;

begin
  n := 0;
  assign(f, 't.txt'); reset(f);
  while not eof(f) do begin
    readln(f, s);
    n := GetWords(n, s, words);
  end;
  close(f);

  for i := 1 to n - 1 do begin

    s := words[i];
    if (s <> words[n]) and (pos(s[1], copy(s, 2, length(s))) > 0)
    then writeln(s);

  end;

end.

Может, кто-то сделает проще ...

как найти последнее слово в строке

На другом форуме было "в тексте". Извини, это ОЧЕНЬ разные вещи!!!