Сортировка: просеивание, Не могу найти ошибку!! Опции

[КрАсАвИцА]

Всем привет! Задача у меня просортировать строки матрицы методом просеивания. По аналогии нашедшейся здесь программы (http://forum.pascalnet.ru/index.php?showtopic=8208 ), сделала свою, но она почему съедает элементы, не могу понять почему. посмотрите пожалуста!

program lab6;
uses crt,pros;
Var
  i,n,j,m: Integer;
  a: matr;
begin
 write('Vvedite koli4estvo strok=');read(n);
 write('Vvedite koli4estvo stolbcov=');read(m);
 writeln('Vvedite e-ti massiva');
 for i:=1 to n do
  begin
   for j:=1 to m do
    read(a[i,j]);
   readln;
  end;
 sort(a,n,m);
 for i:=1 to n do
  begin
   for j:=1 to m do
    write(a[i,j]:3);
   writeln;
  end;
 readkey;
end.

Подключаемый модуль (где впринципе и лежит сортировка):
 
Unit pros;

Interface
 type matr= array[1 .. 100,1..100] of integer;
 procedure sort(var a: matr; n,m: integer);

Implementation
procedure sort;
var
 i,j,t,l : integer;
 begin
  for i:=1 to n do
   for j:=1 To m do
    begin
     t:= a[i,j];
     l:=j-1;
     while (t<a[i,l+1]) and (l>=0) do
      begin
       a[i,l+1]:= a[i,l];
       l:=l-1;
      end;
     a[i,l+1]:=t;
    end;
 end;
end.

Сообщение отредактировано: КрАсАвИцА - 13.01.2006 3:45

[volvo]

Ну, хорошо... Вот процедура, сортирующая матрицу, написанная "как тебя учили":

const
  max_n = 100;
  max_m = 100;

  n = 4;
  m = 4;

Type
  matrix = array[1 .. max_m, 1 .. max_n] of integer;

Procedure Insert(Var ar: matrix; m, n: Integer);
  Var k, i, j, T: Integer;
  Begin
    For k := 1 to m do

      For i := 1 To n do
        Begin
          T := ar[k, i];
          j := i - 1;
          While (T < ar[k, j]) and (j > 0) Do
            Begin
              ar[k, j + 1] := ar[k, j]; Dec(j);
            End;
          ar[k, j + 1] := T;
        End;
  End;

var
  a: matrix;

var
  i, j: integer;

begin
  randomize;
  For i := 1 To m Do
    For j := 1 To n Do
      a[i, j] := Random(20);

  writeln('до:');
  For i := 1 To m Do Begin
    For j := 1 To n Do
      Write(a[i][j]:5);
    WriteLn
  End;

  Insert(a, m, n);

  writeln('после:');
  For i := 1 To m Do Begin
    For j := 1 To n Do
      Write(a[i][j]:5);
    WriteLn
  End;

End.

Разбивай на модули и пользуйся...

Студентик13, ты внимательно смотрел? Про модули слышал когда-нибудь?