Сортировка вставками, Программно реализовать алгоритм сортировки простыми вставками. Опции

[Nelson1992]

Здравствуйте...помогите пожалуйста разобраться с задачей...


Программно реализовать алгоритм сортировки простыми вставками. Каждая запись будет в качестве ключа содержать текстовое выражение, а в качестве информативной части некоторое число.

Тестовый набор записей перед сортировкой необходимо загрузить в память из файла. Файл с тестовым набором необходимо создать. Затем при необходимости изменить у него кодировку (в зависимости от того, в какой ОС Вы осуществляете программную реализацию). После этого для каждой записи берем в качестве ключа слово из исходного файла, а для информативной части его порядковый номер в исходном тексте. Для преобразования текстового файла в набор записей также необходимо выполнить программную реализацию, которая к тому же должна предусматривать создания определенного количества записей.

[Гость]

Вот я вроде бы счётчик времени убрал...но теперь остальное надо убрать...и ещё надо каждому слову присвоить свой порядковый номер который был в исходном файле.

uses crt,dos;
type string10=string[10];
     link_type=^list_type;
     list_type=record value:string10;
                      count:integer;
                      link:link_type;
                end;
     longint_link=^longint;
procedure files_names_query(var read_file,write_file,error:string);
var f:text;
  begin
    error:='';
    write('Считываемый файл: ');
    readln(read_file);
    assign(f,read_file);
    {$I-}
    reset(f);
    if (ioresult=0)
    then
      begin
        close(f);
        write('Файл для записи: ');
        readln(write_file);
      end
    else
      begin
        error:='Ошибка: файл не существует.';
      end;
    {$I+}
  end;
procedure put_into_list(s:string; var root:pointer);
var element,prev_element,new_element:link_type;
    searched:boolean;
  begin
    if (root=nil)
    then
      begin
        new(element);
        root:=element;
        element^.value:=s;
        element^.count:=1;
        element^.link:=nil;
      end
    else
      begin
        searched:=FALSE;
        element:=root;
        prev_element:=nil;
        while ((element<>nil)and(not searched)) do
          begin
            if (element^.value=s)
            then
              begin
                element^.count:=element^.count+1;
                searched:=TRUE;
              end;
            if (prev_element<>nil)
            then
              begin
                if ((prev_element^.value<s)and(element^.value>s))
                then
                  begin
                    new(new_element);
                    new_element^.value:=s;
                    new_element^.count:=1;
                    new_element^.link:=prev_element^.link;
                    prev_element^.link:=new_element;
                    searched:=TRUE;
                  end;
              end
            else
              begin
                if (element^.value>s)
                then
                  begin
                    new(new_element);
                    new_element^.value:=s;
                    new_element^.count:=1;
                    new_element^.link:=element;
                    root:=new_element;
                    searched:=TRUE;
                  end;
              end;
            prev_element:=element;
            element:=element^.link;
          end;
        if (not searched)
        then
          begin
            new(new_element);
            new_element^.value:=s;
            new_element^.count:=1;
            new_element^.link:=prev_element^.link;
            prev_element^.link:=new_element;
          end;
      end;
  end;
procedure reading(read_file:string; var root:pointer);
var simbol:char;
    f:text;
    s:string;
  begin
    s:='';
    assign(f,read_file);
    reset(f);
    while (not eof(f)) do
      begin
        while (not eoln(f)) do
          begin
            read(f,simbol);
            if (simbol<>' ')
            then
              begin
                s:=s+simbol;
              end
            else
              begin
                if (s<>'')
                then
                  put_into_list(s,root);
                s:='';
              end;
          end;
        if (s<>'')
        then
          put_into_list(s,root);
        readln(f,s);
      end;
    close(f);
  end;
procedure writing(root:pointer; write_file:string);
var f:text;
    element:link_type;
    s,count:string;
  begin
    assign(f,write_file);
    rewrite(f);
    element:=root;
    while (element<>nil) do
      begin
        s:=element^.value;
        str(element^.count,count);
        s:=s+'-'+count;
        writeln(f,s);
        element:=element^.link;
      end;
    close(f);
  end;
var read_file,write_file,error:string;
    root:pointer;
begin
  root:=nil;
  if (paramstr(1)<>''){если есть параметры командной строки}
  then{то}
    begin
      read_file:=paramstr(1);{считываемый файл - первый параметр}
      write_file:=paramstr(2);{выходной файл - второй параметр}
      reading(read_file,root);{считывание из файла и сортировка слов}
      writing(root,write_file);{запись в файл}
    end
  else{если нет, то}
    begin
      files_names_query(read_file,write_file,error);{запрос имени файлов через пользовательский инерфейс}
      if (error='')
      then
        begin
          reading(read_file,root);{считывание из файла и сортировка слов}
          writing(root,write_file);{запись в файл}
          writeln('Готово!');
          writeln('Нажмите Enter для продолжения.');
          readln;
        end
      else
        begin
          writeln(error);
          writeln('Нажмите Enter для продолжения.');
          readln;
        end;
    end;
end.