3 задачки на графику, помогите плиз Опции

[phoenix85]

Помогите, пожалуйста, решить 3 задачки в Паскале..
на выходных сдавать, а я в этом ни гу-гу...

есть 3 задачки:

1. сгибающаяся под тяжестью растущего плода ветка;

2. Перемещать три звезды разного цвета в пределах экрана;

3. Построить прямоугольник со сторонами разного цвета и основанием, движущимся согласно процедуре OTREZOK

[Archon]

Ладно, вот код ко второй задаче. Разбирайся, задавай вопросы.

uses
	Graph, Crt;

const
	NumStars = 5;    { Число звезд. }
	StarRadius = 25; { Размер звезд. }
	Step = 1;        { Шаг, с которым перемещаются звезды. }
	FrameDelay = 1;  { Задержка кадра. Попробуй увеличить это значение, }
	                 { если звезды движутся слишком быстро.             }
	
var
	Star: array [0..5] of PointType;
	gd, gm: Integer;
	i: Integer;
	Pos, Offset: array[1..NumStars] of PointType;
	Color: array[1..NumStars] of Word;
begin 
	gd := Detect;
	InitGraph(gd, gm, '');
	
	{ Начальные координаты звезд, направления их движения и цвет задаются случайно. }
	Randomize;
	for i := 1 to NumStars do begin
		Pos[i].x := StarRadius + Random(GetMaxX - 2 * StarRadius);
		Pos[i].y := StarRadius + Random(GetMaxY - 2 * StarRadius);
		Offset[i].x := Step * (1 - 2 * Random(2));
		Offset[i].y := Step * (1 - 2 * Random(2));
		Color[i] := Random(GetMaxColor - 1) + 1;
	end;
	
	{ Вычисление вершин звезды. }
	for i := 0 to 5 do begin
		Star[i].x := Round(Sin(i * Pi * 0.8) * StarRadius);
		Star[i].y := Round(-Cos(i * Pi * 0.8) * StarRadius);
	end;

	{ Основной цикл. }
	repeat
		for i := 1 to NumStars do begin
			{ Стираем звезду. }
			SetColor(Black);
			SetViewPort(Pos[i].x, Pos[i].y, Pos[i].x, Pos[i].y, false);
			DrawPoly(6, Star);
			
			{ Меняем положение звезды. }
			Inc(Pos[i].x, Offset[i].x);
			Inc(Pos[i].y, Offset[i].y);
			
			{ Если звезда достигла края экрана, меняем направление ее движения. }
			if (Pos[i].x < StarRadius) or (Pos[i].x > GetMaxX - StarRadius) then
				Offset[i].x := -1 * Offset[i].x;
			if (Pos[i].y < StarRadius) or (Pos[i].y > GetMaxY - StarRadius) then
				Offset[i].y := -1 * Offset[i].y;
			
			{ Рисуем звезду в новом месте. }
			SetColor(Color[i]);
			SetViewPort(Pos[i].x, Pos[i].y, Pos[i].x, Pos[i].y, false);
			DrawPoly(6, Star);
		end;
		{ Задержка, чтобы кадры не сменяли друг друга слишком быстро. }
		Delay(FrameDelay);
	until KeyPressed;
	
	CloseGraph;
end.