Игровая программа, таймер и генерация звука Опции

[Rocket]

Доброго времени суток, уважаемые форумчане! Мне нужно написать программу, которая перед началом игры произвольно устанавливает невидимую на экране метку и видимый символ "*", который перемещается по экрану с помощью стрелок. При движении символа генерируются звуковые колебания, частота которых зависит от расстояния до невидимой метки. Если метка не найдена за 4 секунды, метка перемещается в другую точку.
Мне очень эта программа напоминает металлоискатель : )
Пока что я сделал только перемещение символа "*" с помощью букв w,s,a,d.

data segment

	old_cs		dw ?		
	old_ip		dw ?

	symbol		db ?
	Pressed		db 1

	x db ?
	y db ?

	sgn		db '*'
	atr		db 10

data ends

code segment
	assume cs: code, ds: data


new_1c proc far

	
	push ax
	push bx
	push ds
	push es
	
	
	mov  ax, data
	mov  ds, ax
	
	
	mov  ax, 40h		
	mov  es, ax
	mov  ax, es:[1Ch]	
	mov  bx, es:[1Ah]	
	cmp  bx, ax		
	jne  get_char		
	
	
	jmp  go_out

get_char:
	mov  al, es:[bx]	
	mov  es:[1Ch], bx	
	mov symbol, al
	inc Pressed		
	
go_out:
	pop  es
	pop  ds
	pop  bx
	pop  ax
	iret
new_1c endp

start:
	mov  ax, data
	mov  ds, ax
	
	
	mov  ah, 35h
	mov  al, 1Ch
	int  21h
	
	mov  old_ip, bx
	mov  old_cs, es
	
	
	push ds			
	mov  dx, offset new_1c
	mov  ax, seg new_1c
	mov  ds, ax
	mov  ah, 25h
	mov  al, 1Ch
	int  21h		
	pop  ds
	
	mov  ax, data
	mov  es, ax

	mov x,14
	mov y,40	

main_loop:
	
	cmp Pressed, 0		
	je m1


	mov Pressed, 0
	cmp symbol, 30h
	je q
	
	xor ax, ax
	mov al, symbol


m1:	cmp al, 'w'
	jne m2
	dec x
	jmp met

m2:	cmp al, 's'
	jne m3
	inc x
	jmp met

m3:	cmp al, 'a'
	jne m4
	dec y
	jmp met

m4:	cmp al, 'd'
	jne main_loop
	inc y
	

	
met: 	xor bh, bh
	mov ah, 13h		
	mov al, 0d
	mov dh, x
	mov dl, y
	lea  bp, sgn		
	mov  cx, 1		
	mov  bl, atr
	int 10h
			
jmp main_loop

q:

	push ds
	
	mov  dx, old_ip 
	mov  ax, old_cs
	mov  ds, ax
	mov  ah, 25h
	mov  al, 1Ch
	int  21h
	pop  ds
	
	mov  ax, 4C00h	
	int  21h
code ends
end start

Не могу понять, почему "вверх" не срабатывает с первого раза? приходится повторно нажимать "w", в результате мы поднимаеся не на одну позицию, а на две...
И как сделать какую-нибудь очистку экрана? чтоб очищать консоль и на экран выводился только один символ "*" .

[volvo]

По поводу генерации звуков - когда-то 7in на одном из форумов приводил вот такие процедуры:

; Процедура Sound: генерация звука
; Вход: AX = частота звука (Гц)
Sound proc
	xchg bx, ax	; Частота
	mov dx, 12h	; (DX,AX)=1193181
	cmp bx, dx	; Если Bx <= 18Гц, то выход
	jbe Done		; Чтобы избежать переполнения
	in al, 61h		; Порт РВ
	or al, 3		; Установить биты 0-1
	out 61h, al
	mov al, 10110110b	; Управляющее слово таймера:
					; канал 2, режим 3, двоичное слово
	out 43h, al	; Вывод в регистр режима
	mov ax, 34DDh
	div bx		; AX=(DX:AX)/BX
	out 42h, al	; Младший байт счетчика
	mov al, ah
	out 42h, al	; Старший байт счетчика
Done:
	ret
Sound endp

;-------------------------------------------------;

; Процедура NoSound: выключение звука
NoSound proc
	in al, 61h		; Порт РВ
	and al, not 3	; Сброс битов 0-1
	out 61h, al
	ret
NoSound endp

У него же были и Randomize + Random, но поскольку кое-что тебе уже подсказали по поводу случайных чисел, то повторяться не буду...

[Rocket]

По поводу генерации звуков - когда-то 7in на одном из форумов приводил вот такие процедуры:
У него же были и Randomize + Random, но поскольку кое-что тебе уже подсказали по поводу случайных чисел, то повторяться не буду...

Использую эту процедуру в программе, динамик издаёт однократный треск. А как сделать именно дискретное "пиканье" через всё выполнение программы? и чтоб частота этого "пиканья" зависела от расстояния до невидимой точки...?