График с файла, Надеюсь последний...)) Опции

[yakudza_m]

Привет вам, админы!!!
Ваши проги привели моих однокурсников в шок)))
А преподы, кажется, что-то задумали...(
В общем мне нужен совет по поводу графика функции...

Нужно протабуллировать функцию y=arccos(x) в области [-0.99; 0.99], результаты занести в файл, а потом из этого же файла по результатах построить график...нужно чтоб сам график рисовался точками толщиной в 3 пикселя, тёмно-серым цветом, а подписи к обозначениям длины на осях были в стиле Gothic...фух...вот это загнули...я сам чуть не лишился дара речи от такого...оси примерно такие как в файле, который добавляю...

[volvo]

А вот, кстати, и подтверждение, что приведенная функция - именно АркКосинус:

program argcos1;
Uses graph;

function ArcCos(x: real): real;
begin
  if Abs(x) < 10E-3 then ArcCos := Pi/2
  else ArcCos := ArcTan(Sqrt(1 - Sqr(x)) / x) + Pi * Byte(x < 0)
end;

type
  Trecord = record
    x: real;
    y: real;
  end;
  Tfile = file of Trecord;

const
  eps = 0.01;
  scaleX = 250;
  scaleY = 100;

var
   a:Trecord;
   f:Tfile;
   grD :integer;
   grM :integer;
   errC:integer;

   dbl: real;
   s: string;
begin
  assign(f,'file.rec'); rewrite(f);

  a.x := -1 + eps;
  while a.x < 1 do begin
    a.y := arccos(a.x);
    write(f, a);
    a.x := a.x + eps;
  end;
  close(f);

  initgraph(grd, grm, '');
  errc := graphresult;
  if errc = grOk then begin
    setcolor(lightred);
    line(20, 3 * getmaxy div 4, getmaxx - 20, 3 * getmaxy div 4);
    line(getmaxx div 2, 20, getmaxx div 2, getmaxy - 20);

    settextstyle(gothicfont, horizdir, 1);
    settextjustify(centertext, centertext);

    dbl := -1;
    while dbl <= 1 do begin
      str(dbl:4:2, s);
      outtextxy((getmaxx div 2) + trunc(dbl * scaleX),
                (3 * getmaxy div 4) + 20, s);
      dbl := dbl + 0.25;
    end;

    reset(f);
    read(f, a);
    setcolor(lightgray);
    setlinestyle(solidLn, 0, thickWidth);
    moveto((getmaxx div 2) + trunc(scaleX * a.x),
           (3 * getmaxy div 4) - trunc(scaleY * a.y));
    while not eof(f) do begin
      read(f, a);
      lineto((getmaxx div 2) + trunc(scaleX * a.x),
             (3 * getmaxy div 4) - trunc(scaleY * a.y));
    end;
    close(f);

    readln;
    closegraph;
  end;
end.

(файлы EGAVGA.BGI и GOTH.CHR из папки \BGI должны быть в одной папке с программой. Можно, конечно, слинковать их с основной программой вот так , но я думаю ЭТОГО твои преподаватели, yakudza_m, тебе точно не простят)...

Добавлено через 5 мин.

а причем оси?

А при том, что если в твоем рисунке (в первом) ось OX будет на 8 клеточек выше, то "легким движением руки график превращается... превращается график..." (С) в противоположный. Нет вообще такой кривой: Косинусоида. Есть синусоида, только иногда она сдвигается... Теперь понимаешь, о чем я?