Строки Опции

[JoKe]

Среди нескольких предложений найдите то, которое содержит наибольшее количество разных букв.
Задачу решить с использованием процедур.

[volvo]

Идея такая: символы, которые уже встречались, хранишь в строке, проверять очень удобно, если pos возвращает ненулевой результат, то буква уже была, если ноль - то еще не было. "Помечать" символ уже существующим тоже удобно: просто добавить его к строке... Вот так, например (я все прокомментировал, попробуй разобраться, если чего не понятно - спрашивай).

procedure check_letters(ch: char; var letrs: string);
begin
  {
    Проверяем, встречался ли уже символ раньше в этом предложении,
    если не было - добавляем его к строке
  }
  if pos(ch, letrs) = 0 then letrs := letrs + ch;
end;

var
  s, sent, max_sent, letters: string;
  i, max_let: integer;
begin
  s := 'abcd  def. bbabbde yrye, trtkj! defrertyyl? trtll.'; { исходная строка }
  sent := ''; letters := ''; max_sent := ''; max_let := 0;
  for i := 1 to length(s) do begin { пробегаем по всем символам строки }

    if s[i] in ['.', '!', '?'] then begin { закончилось предложение? }
      if length(letters) > max_let then begin { разных букв больше, чем максимальное до сих пор количество? }
       { Да, запоминаем новый максимум, и запоминаем предложение}
        max_let := length(letters); max_sent := sent;
      end;

      { В любом случае подготовимся к обработке следующего предложения: обнулим все, что нужно }
      sent := ''; letters := '';
    end
    else begin
      {
        Нет, предложение еще не закончилось. Добавляем букву в sent ("собираем" из букв
        само предложение), и проверяем, встречалась ли s[ i ] до сих пор - процедурой
      }
      sent := sent + s[i];
      check_letters(s[i], letters);
    end;

  end;

  { Все, печатаем результат }
  writeln('Предложение: "', max_sent, ' " содержит ', max_let, ' разных символов');
end.