Обработка символьной информации, с помощью функций DOS Опции

[Rocket]

Вот задание: Ввести с клавиатуры две строки. Сравнить их. Вывести на экран какая из строк больше и насколько. Какие мысли есть по реализации данной программы? Как осуществить сравнение строк?

[volvo]

А вот как организовать подпрограмму поиска одной введённой строки в другой строке? И ещё: вывод позиции, с которой подстрока содержится в строке...

Вот тебе программа, которая это делает... В виде подпрограммы оформляй сам:

MODEL small

stack 100
.286

DATASEG
entrStr	db 13, 10, 'string:$'
entrSStr	db 13, 10, 'substring:$'
sNotFound	db 13, 10, 'substring was not found$'
sResult	db 13, 10, 'pos = $'

inpStr  db 200
inpStrLen db ?
inpStrDat db 200 dup(?)

inpSStr  db 200
inpSStrLen db ?
inpSStrDat db 200 dup(?)

count_of_digits  dw 6

CODESEG

writeDEC proc

	; ...

writeDEC endp

show_ax proc
	mov cx, 10
	xor di, di
@@conv:
	xor dx, dx
	div cx
        add dl, '0'
        inc di
	push    dx              ; складываем в стэк
        or      ax, ax
        jnz     @@conv
        ; выводим из стэка на экран
    @@show:
        pop     dx              ; dl = очередной символ
        mov     ah, 2           ; ah - функция вывода символа на экран
        int     21h
        dec     di              ; повторяем пока di<>0
        jnz     @@show
        ret
show_ax endp

start: 
	mov ax,@DATA
	mov ds, ax
	mov es, ax
	
	; вводим строку
	mov ah, 09h
	mov dx, offset entrStr
	int 21h
	mov ah, 0ah
	mov dx, offset inpStr
	int 21h
	
	; записываем '$' в конец строки
	mov di, offset inpStrDat
	xor ch, ch
	mov cl, inpStrLen
	add di, cx
	mov byte ptr[di], '$'
	
	; вводим подстроку
	mov ah, 09h
	mov dx, offset entrSStr
	int 21h
	mov ah, 0ah
	mov dx, offset inpSStr
	int 21h
	
	; Подготовка
	xor cx, cx
	mov di, offset inpStrDat
	mov si, offset inpSStrDat
	mov cl, inpStrLen
	
	; Ищем первый символ подстроки
FindFirstCh:
	mov al, [di] ;
	inc di
	cmp al, [si]
	jz beginCompare	; Нашли
	
nextCompare:
	loop FindFirstCh

	; Если цикл FindFirstCh закончился - значит подстроки нет
	mov ah, 09h
	mov dx, offset sNotFound
	int 21h
	jmp exit_prog
	
beginCompare:
	; Проверяем следующие за первым в подстроке символы
	push cx
	push si
	push di
	dec di
	mov cl, inpSStrLen
	
	; Проверка
yesCompare:
	mov al, [di]
	inc di
	cmp al, [si]
	jnz noCompare	; Очередной символ не совпал
	inc si
	loop yesCompare
	
	; Если здесь - значит все совпало
	jmp found
	
	; Не совпало - восстанавливаем данные и ищем дальше
	; первый символ подстроки в строке
noCompare:
	pop di
	pop si
	pop cx
	jmp short nextCompare
	
found:
	; Есть совпадение, выводим сообщение
	mov ah, 09h
	mov dx, offset sResult
	int 21h
	
	; вытягиваем из стека адрес первого символа
	pop di
	
	; и вычисляем его позицию
	mov dx, offset inpStrDat
	mov ax, di
	sub ax, dx
	call writeDEC	; Эту процедуру я показывал раньше
	
exit_prog:
	mov ah, 4ch
	int 21h
end start

(процедуру writeDEC возьми из предыдущих постов, я не стал ее опять копировать...)

[Rocket]

Вот тебе программа, которая это делает...

У меня возник ряд вопросов по реализации...
1) Использование "offset". Я так полагаю, что это полный аналог команды "lea" ?
2) inpStrDat что это за переменная, для чего она нужна?
3)

mov di, offset inpStrDat

что делает конструкция такого вида?
4) Как определяется размер строки? т.е.

mov cl, inpStrLen

почему в cl сразу помещается размер строки?
5) При переходе на метку

beginCompare:

, где мы должны проверять последующие за первой буквы, мы снова проверяем совпадение первых букв, так ли это?
6) Когда мы из стека вытаскиваем di, разве он сразу не указывает на позицию, с которой начинается подстрока в строке? Как вообще происходит тогда вычисление позиции?

Сообщение отредактировано: volvo - 14.01.2009 0:28

[volvo]

1) Использование "offset". Я так полагаю, что это полный аналог команды "lea" ?

Правильно полагаешь...

; можно вот так получить смещение inpStrDat
; в сегменте данных
mov di, offset inpStrDat

; а можно - вот так:
lea di, inpStrDat

В обоих случаях смещение этого массива от начала сегмента будет занесено в регистр DI...

2) inpStrDat что это за переменная, для чего она нужна?

Как это "для чего"? А строку ты что, в воздухе хранить будешь? Вообще-то для нее надо место выделять. Вот я и выделил 200 байт.

Вообще обрати внимание, для ввода строки используется функция 0AH прерывания 21H... А она требует для работы вот чего:

LABEL представляет собой директиву с атрибутом BYTE. Первый байт содержит максимальную длину вводимых данных. Так как это однобайтовое поле, то возможное максимальное значение его - FFh или 255. Второй байт необходим DOS для занесения в него действительного числа введенных символов. Третьим байтом начинается поле, которое будет содержать введенные символы.

 	NAMEPAR	LABEL BYTE	; Список параметров:
	MAXLEN	DB 20		; Максимальная длина
	ACTLEN	DB ?		; Реальная длина
	NAMEFLD	DB 20 DUP (' ')	; Введенные символы

Так как в списке параметров директива LABEL не занимает места, то NAMEPAR и MAXLEN указывают на один и тот же aдрес памяти. В трансляторе MASM для определения списка параметров в виде структуры может использоваться также директива STRUC. Однако, в связи с тем, что ссылки на имена, определенные внутри, требуют специальной адресации, воздержимся cейчас от рассмотрения данной темы до гл. 24 "Директивы ассемблера".
Для запроса на ввод необходимо поместить в регистр AH номер функции - 10 (шест. 0Ah), загрузить адрес списка параметров (NAMEPAR в нашем примере) в регистр DX и выполнить INT 21H

Вот так... А поскольку я не описывал LABEL (ленивый я, не люблю набирать лишние символы ), то в DX загружал смещение inpStr, то есть, первого из необходимых параметров...

Я надеюсь, вопрос

4) Как определяется размер строки? т.е.

mov cl, inpStrLen

почему в cl сразу помещается размер строки?

исчерпан? Я там, в цитате, выделил ответ на него...

5) При переходе на метку

beginCompare:

, где мы должны проверять последующие за первой буквы, мы снова проверяем совпадение первых букв, так ли это?

Так, но почему тебя это пугает? Я же уменьшаю DI перед проверкой, то есть, DI указывает именно на первый, совпавший символ в строке...

6) Когда мы из стека вытаскиваем di, разве он сразу не указывает на позицию, с которой начинается подстрока в строке? Как вообще происходит тогда вычисление позиции?

Нет, он указывает на смещение относительно начала сегмента... А для того, чтобы вычислить позицию, надо из этого самого смещения, которое хранится в DI, вычесть смещение первого символа строки, которое я и заношу в DX... После вычитания в AX имеем позицию подстроки в строке...