OS DOS!!! Отследить изменения FAT таблици Опции

[USA]

Всем привет!!
Если у когото есть на PC раздел ДОС и утилита DISKEDIT.
Подскажите  как выполнить следующее???:
Отследить изменения  в оглавлении каталога и таблице FAT при создании, удалении и восстановлении файлов?????

Оформление результатов:
Отчет с подробным описанием динамики изменений в системной области диска при манипуляциях с файлами (создание, удаление и пр.).

Если кто то делал данную работу или кто знает каким еще способом  можно сделать этот анализ, подскажите пожалуйста!!!!!! :'(

[P@sh@]

эта прога рисует карту диска в формате FAT16, ну и попутно некоторую инфу выдает

... (Показать/Скрыть)

uses Crt,Graph;
type Sector=array[0..511] of byte;
     CBlockType=record
       Sector:longint;
       Number:word;
       BufPtr:pointer;
     end;
     BPBRec=record
       BootRecPtr:array[1..3] of byte;
       OEMIDstr  :array[1..8] of char;
       BytePerSec:word;
       SecPerClus:byte;
       ReservSecs:word;
       FATcopies :byte;
       RootItems :word;
       TotalSec16:word;
       Descriptor:byte;
       FATsectors:word;
       SecPerTrak:word;
       Heads     :word;
       HideSector:longint;
       TotalSec32:longint;
       DiskNumber:word;
       Signature :byte;
       SerialNum :longint;
       VolumeLabel:array[1..11] of char;
       SystemIDstr:array[1..8] of char;
     end;
var  BootSector,FATsector:Sector;
     BPB:^BPBRec;
     LastResult,FirstDataSector,Clusters:word;
     dr:char;

procedure ReadDisk32(Drive:byte; CB:pointer);
assembler;
asm
  push ds
  lds  bx,CB
  mov  al,Drive
  mov  cx,-1
  int  25h
  add  sp,2
  pop  ds
  mov  LastResult,ax
  xor  ax,ax
  jc   @e
  mov  LastResult,ax
@e:
end;
procedure ReadSectors(Drive:byte; S:longint; N:word; Buf:pointer);
var CB:CBlockType;
begin
  with CB do begin
    Sector:=S;
    Number:=N;
    BufPtr:=Buf;
  end;
  ReadDisk32(Drive,@CB);
end;
procedure Block(x,y,ny:integer; c:byte);
begin
{  SetFillStyle(1,8+c); bar(x,y,x+2,y+ny-2);}
  SetColor©; line(x+1,y,x+1,y+ny-1); line(x,y+ny-1,x+1,y+ny-1);
  SetColor(8+c); line(x,y,x,y+ny-2);
end;
var d,i,n,s,ny:word;
    x,y:integer;
    c:byte; x4:boolean;
begin
  write('Диск: '); readln(dr); dr:=upcase(dr);
  ReadSectors(ord(dr)-65,0,1,@BootSector);
  writeln(LastResult);
  writeln('Загрузочный сектор диска ',dr,': (блок параметров BIOS)');
  writeln; BPB:=@BootSector;
  with BPB^ do begin
    FirstDataSector:=ReservSecs+FATsectors*FATcopies+RootItems div 16;
    Clusters:=2+(TotalSec32-FirstDataSector) div SecPerClus;
    writeln('                OEM ID: ',OEMIDstr);
    writeln('        Байт в секторе: ',BytePerSec);
    writeln('   Секторов в кластере: ',SecPerClus);
    writeln('    Резервных секторов: ',ReservSecs);
    writeln('      Кол-во копий FAT: ',FATcopies);
    writeln('    Элементов на корню: ',RootItems);
    writeln('    Секторов(до 65535): ',TotalSec16);
    writeln('      Дескриптор диска: ',Descriptor);
    writeln('       Секторов на FAT: ',FATsectors);
    writeln('   Секторов на дорожку: ',SecPerTrak);
    writeln('        Кол-во головок: ',Heads);
    writeln('      Скрытых секторов: ',HideSector);
    writeln('        Всего секторов: ',TotalSec32);
    writeln('Физический номер диска: ',DiskNumber);
    writeln('  Сигнатура загрузчика: ',Signature);
    writeln('        Серийный номер: ',SerialNum);
    writeln('            Метка том : ',VolumeLabel);
    writeln('             System ID: ',SystemIDstr);
    writeln('  Первый сектор данных: ',FirstDataSector);
    writeln('       Всего кластеров: ',Clusters);
    s:=ReservSecs;
  end;
  writeln('Нажмите любую клавишу для вывода карты диска');
  readkey;
  x:=VGA; y:=2;
  InitGraph(x,y,'c:programpascalbgi');
  Block(0,456,8,7); OutTextXY(8,456,'-Free cluster');
  Block(0,472,8,3); OutTextXY(8,472,'-Used cluster');
  Block(160,456,8,1); OutTextXY(168,456,'-Last (or only)');
  Block(160,472,8,6); OutTextXY(168,472,'-FAT ID');
  Block(320,456,8,4); OutTextXY(328,456,'-Bad cluster');
  ny:=456 div (Clusters div 320+1);
  i:=0; x:=i*2; y:=0; n:=i*2;
  ReadSectors(ord(dr)-65,s,1,@FATsector);
  while i<=Clusters do begin
    d:=FATsector[n]+FATsector[n+1]*256;
    case d of
    $0000: c:=7;
    $FFF7: c:=4;
    $FFF8: c:=6;
    $FFFF: c:=1;
    else c:=3;
    end;
    Block(x,y,ny,c);
    x:=x+2; if x=640 then begin x:=0; y:=y+ny; end;
    i:=i+1; n:=n+2;
    if n=BPB^.BytePerSec then begin
      n:=0; s:=s+1;
      ReadSectors(ord(dr)-65,s,1,@FATsector);
    end;
  end;
  readkey;
  CloseGraph;
end.

изменения в FAT-таблице появятся при создании (в том числе копировании), увеличении размера и удалении файла. При перемещении на самом деле файл никуда не двигается, просто его заголовок переносится из одного каталога в другой. Каталог для FATа - тот же файл, только с атрибутом "каталог", который содержит в качестве данных заголовки файлов. Правда есть еще корневой каталог - он занимает фиксированное положение сразу за FAT-таблицей и не регистрируется в ней. При удалении файла/каталога первая буква его имени затирается кодом 01, а первый его кластер в FAT-таблице объявляется свободным (механизм удаления еще надо уточнить, я точно не помню)