Сосчитать количество чисел в десятичной записи числа, А также...нахождение радиуса... Опции

[Archie]

1) Подсчитать количество (k) цифр в десятичной записи целого неотрицательного числа n.
2) Даны натуральное n и вещественные числа x1,y1,x2,y2,...,xn,yn. Рассматривая пары xi и yi как координаты точек на плоскости, определить радиус наименьшего круга (с центром в начале координат), внутрь которого попадают все эти точки.
В паскале плохо шарю и плохо его помню...а тут такое дело - завтра лабораторную эту сдавать а я не могу даже вникнуть...прошу помочь...

Сообщение отредактировано: Archie - 16.09.2007 17:48

[klem4]

{$R-}
uses crt, graph;

type

  TPoint = record
    x, y: integer;
  end;

const
  zero: TPoint = (x:0; y:0);

type

  PArray = ^TArray;
  TArray = array [1..1] of TPoint;

function get_len(const a, b: TPoint): Single;
begin
  get_len := sqrt(sqr(a.x - b.x) + sqr(a.y - b.y));
end;

function FloatToStr(const fValue: single): String;
begin
  str(fValue:5:2, FloatToStr);
end;

var
  gd, gm, cx, cy, mx, my: integer;

  i, n: integer;

  len, max_len: single;

  points: PArray;

begin
  gd := detect;
  initgraph(gd, gm, '');

  mx := getMaxX;
  my := getMaxY;

  cx := mx div 2;
  cy := my div 2;

  setColor(RED);

  line(cx, 0, cx, my);
  line(0, cy, mx, cy);

  n := 150;

  GetMem(points, n * sizeof(TArray));

  randomize;

  setColor(BLUE);
  setFillStyle(SOLIDFILL, blue);

  for i := 1 to n do begin

    points^[i].x := random(301) - 150;
    points^[i].y := random(301) - 150;

    fillellipse(cx + points^[i].x, cy - points^[i].y, 2, 2);
  end;

  max_len := get_len(zero, points^[1]);

  for i := 2 to n do begin
    len := get_len(zero, points^[i]);
    if len > max_len then
     max_len := len;
  end;

  setColor(WHITE);

  circle(cx, cy, round(max_len));

  outTextXY(1, 1, 'R = ' + FloatToStr(max_len));

  readkey;

  closegraph;
  FreeMem(points, n * sizeof(TArray));
end.

Сообщение отредактировано: klem4 - 16.09.2007 21:31