двумерный массив Опции

[KATYSHA]

Помогите плиз,вообще не в зуб ногой ...............я скоро повешусь.Помогите пожалуйста решить задачу: дана матрица вещественных чисел.заменить максимальный элемент в каждой строке суммой положительных элементов,а минимальный-суммой отрицательных.

Заранеее ОГРОМНОЕ СПАСИБО

[volvo]

Самый простой вариант:

const
  m = 3; { число строк }
  n = 4; { число столбцов }

var
  a: array[1 .. m, 1 .. n] of real;
  i_min, i_max, i, j: integer;
  sum_plus, sum_minus: real;
begin
  { ввод матрицы }
  for i := 1 to n do
    for j := 1 to n do begin
      write('a[', i:3, j:3, '] = '); readln(a[i, j]);
    end;


  for i := 1 to m do begin

    sum_plus := 0; sum_minus := 0;
    i_min := 1; i_max := 1;
    for j := 1 to n do begin
      if a[i, j] < a[i, i_min] then i_min := j;
      if a[i, j] > a[i, i_max] then i_max := j;

      if a[i, j] < 0 then sum_minus := sum_minus + a[i, j]
      else sum_plus := sum_plus + a[i, j];
    end;
    a[i, i_min] := sum_minus;
    a[i, i_max] := sum_plus;

  end;

  { вывод матрицы }
  for i := 1 to n do begin
    for j := 1 to n do
      write(a[i, j]:6:2);
    writeln;
  end;

end.

[KATYSHA]

Самый простой вариант:

Спасибо огромное!!!

[KATYSHA]

А как со сроками сделать и файлами?Помоги ещё разок пожалуйста.
1.
Дана строка символов.Группы символов,разделенные одним или несколькими пробелами и не содержащие пробелов внутри себя,будем называть словами.получить логический вектор,элемент которого истина,если в слове четное кол-во символов и ложь-впротивном случае.
2.
Дан файл вещественных чисел.Если среднее арифметическое его компонент превышает значение максимального эл-та файла,удалить из него все отрицательные эл-ты,в противном случае- удалить все положительные.

ЗАРАНЕЕ СПАСИБО ОГРОМНОЕ ПРЕОГОРОМНОЕ!!!!!

[klem4]

Эхх, я тут посмотрел, на форуме начались дни добрых дел и выкладывания полных решений, так что держи :

про строки

uses crt;

const

   limits = [#0..#32,'.',',',':',';','!','?','"'];
type

   TWords = array[1..40] of string;
   TLogic = array[1..40] of boolean;

var
   text  : string;
   words : TWords;
   logic : TLogic;

function GetWords(s : string; var w : TWords; var L : TLogic) : byte;
var
   i,back,n : byte;
begin
   i := 1;
   n := 0;
   while(i<=length(s)) do begin
      while(i<=length(s)) and (s[i] in limits) do
       inc(i);
      if i<=length(s) then begin
         back := i;
         while(i<=length(s)) and not(s[i] in limits) do
          inc(i);
         inc(n);
         w[n] := copy(s, back, i-back);
         L[n] := not(odd(length(w[n])));
      end;
   end;

   GetWords := n;
end;

var
   i,j : byte;

begin

   clrscr;

   write('text = '); readln(text);

   j := GetWords(text, words, logic);

   for i := 1 to j do writeln(words[i],' ', logic[i]:10);

   readln;

end.

[hiv]

2. Дан файл вещественных чисел.Если среднее арифметическое его компонент превышает значение максимального эл-та файла,удалить из него все отрицательные эл-ты,в противном случае- удалить все положительные.

Cреднее арифметическое компонентов файла всегда будет меньше или равно значению максимального эл-та файла. Может имелось в виду последнего элемента файла?

[KATYSHA]

Спасибо огромное!!!! А можно узнать кем ты работаешь???

Добавлено (через 4 минуты):

Cреднее арифметическое компонентов файла всегда будет меньше или равно значению максимального эл-та файла. Может имелось в виду последнего элемента файла?

Я переписала задание как есть

[klem4]

Я переписала задание как есть

Тогда решение будет бессмысленно ... Уточни задание у препода.

[KATYSHA]

препод говорит,что всё правильно и думать надо

[volvo]

KATYSHA, это невозможно...
Когда среднее арифметическое N элементов максимально? Когда все эти элементы одинаковы, так?

Допустим, все элементы одинаковы и равны "Х", тогда и среднее арифметическое равно "X". РАВНО, но не БОЛЬШЕ !!! Увеличим один элемент на значение "Y", тогда ср. арифметическое увеличится на Y/N, что заведомо меньше чем Y... Так что ср. арифметическое просто НЕ МОЖЕТ быть больше макс. элемента массива...

Так что пускай твой препод сам пошевелит тем, что у него вместо мозгов, и даст другое задание или переформулирует это...

[KATYSHA]

Кстати,эта программка не работает,klim4(которую ты вначале писал мне) Когда вводишь значения,они как бы по кругу идут...............что-то там не то.И объясни,пли з,что за строка вначале limits и почему там в скобках с решеткой числа???

Сообщение отредактировано: KATYSHA - 18.11.2005 10:42

[volvo]

To: KATYSHA
Пример значений, которые вводишь, приведи... Ненадо просто так говорить, что программа "не работает"... Тестируем мы программы все-таки...

[KATYSHA]

Ну программа то работает,но как-то неправильно.там не должно быть столько значений,когда запускаешь её.Там появляется очень много векторов

[volvo]

Замени основную программу вот на такую:

begin
   clrscr;
   write('text = '); readln(text);
   j := GetWords(text, words, logic);
   for i := 1 to j do write(logic[i]:6);
   writeln;

   readln;
end.

получишь распечатку только "логического" вектора...

[KATYSHA]

Спасибо,попробую.Если не так я скажу или покажу примерную программу,потому что я просто не могу объяснить как именно она должна выглядеть.

[KATYSHA]

Эхх, я тут посмотрел, на форуме начались дни добрых дел и выкладывания полных решений, так что держи :

про строки

uses crt;

const

   limits = [#0..#32,'.',',',':',';','!','?','"'];
type

Обьясни пожалуйста что за строка такая limits ???? можно как нибудь обойтись в программе без этого limits ну или хотя бы заменить как-нибудь её?

[volvo]

KATYSHA, это список символов, которыми могут разделяться слова. Следовательно, обойтись без этого можно ТОЛЬКО тогда, когда ты на 100% уверена, что ничего кроме пробелов для разделения слов во введенной тобой строке использоваться НЕ будет...
Тогда поменяй в функции вот так:

   while(i<=length(s)) do begin
      while(i<=length(s)) and (s[i] = ' ') do inc(i);
      if i<=length(s) then begin
         back := i;
         while(i<=length(s)) and (s[i] <> ' ') do inc(i);
         inc(n);
         w[n] := copy(s, back, i-back);
         L[n] := not(odd(length(w[n])));
      end;
   end;

[KATYSHA]

Это вначале поменять вместо той строки?или это по-моему в середине где-то должно быть кажись

[arhimag]

Я думаю что гдето в середине!

[volvo]

Я думаю что гдето в середине!

В середине... Вместо почти аналогичного куска в программе klem4
Вот так будет выглядеть измененная функция GetWords полностью:

function GetWords(s : string; var w : TWords; var L : TLogic) : byte;
var
   i,back,n : byte;
begin
   i := 1;
   n := 0;
   while(i<=length(s)) do begin
      while(i<=length(s)) and (s[i] = ' ') do inc(i);
      if i<=length(s) then begin
         back := i;
         while(i<=length(s)) and (s[i] <> ' ') do inc(i);
         inc(n);
         w[n] := copy(s, back, i-back);
         L[n] := not(odd(length(w[n])));
      end;
   end;

   GetWords := n;
end;