Массив, процедура и модуль, Помогите избавиться от ошибки 26 Опции

[Юрий]

Помогите, пожалуйста, найти ошибку, голову сломал:
Есть процедура, в которой в качестве параметра используется массив. Все работает:

Type matr=array [1..2,1..10] of real;
Var P:matr;
...
Procedure FN (Var P:matr; k:integer);
Begin
  For k:=1 to 10 do
    if P[1,k]<0 then
     begin
      P[1,k]:=0;
      P[2,k]:=P[2,k]+R
     end
end;
...
Begin
...

 if R0<R then FN(P,J);

Но если выношу процедуру в отдельный модуль, то при точно таком же вызове процедуры после FN(P, компилятор дает ошибку 26. Что делаю не так? Пробовал в описании процедуры убирать Var, не помогло.

Unit Dva;
 Interface
   Type matr=array [1..2,1..10] of real;
   Var P:matr;

       R:real;

   Procedure FN (Var P:matr);

 Implementation
  Procedure FN;
   var
    k:integer;
    Begin
      For k:=1 to 10 do
        if P[1,k]<0 then
          begin
            P[1,k]:=0;
            P[2,k]:=P[2,k]+R
          end;
    end;
  end.

[volvo]

Procedure FN (Var P:matr);

- ожидается один параметр. Ты пытаешься передать 2, как было без модуля.

Зачем поменял заголовок процедуры? Количество и порядок следования параметров должны быть неизменны, если хочешь вызывать подпрограмму так же, как и раньше...

[Юрий]

Это я уже экспериментировал. Вернул все как было. Ошибка осталась. Вот коды основного модуля и модуля с процедурой:

Program Osnova;
 Uses Odin, Dva;

 Type matr=array [1..2,1..10] of real;

 Var
   P:matr;
   i,J:integer;
   f1,f2:text;
   R,R0:real;

 Begin
 assign(f1,'C:\pascal\is.txt');
 assign(f2,'C:\pascal\vd.txt');
 reset(f1);
 rewrite(f2);

 {vvod R}
 write('Input R: ');
 readln(r);

 for i:=1 to 2 do
  for J:=1 to 10 do
   begin
    read(f1,P[i,j]);
   end;

 j:=0;
 repeat
  j:=j+1;
  R0:=rast(P[1,J],P[1,J+1],P[2,J],P[2,J+1]);
 until R0<R;

 if R0<R then
  begin
   for i:=1 to 10 do FN(P,J);

  writeln(f2,' ':35,'Rezyltat');
  writeln(f2);

  for i:=1 to 2 do
   begin
    for j:=1 to 10 do
     write(f2,' ':3,P[i,J]:6:3);
    writeln(f2);
   end;

close(f1);
close(f2)
end;
end.

Unit Dva;
 Interface
   Type matr=array [1..2,1..10] of real;
   Var P:matr;
       k:integer;
       R:real;

   Procedure FN (Var P:matr, k:integer);

 Implementation
  Procedure FN;
    Begin
      For k:=1 to 10 do
        if P[1,k]<0 then
          begin
            P[1,k]:=0;
            P[2,k]:=P[2,k]+R
          end;
    end;
  end.

[volvo]

Procedure FN (Var P:matr,  k:integer);

там должна стоять точка с запятой, а не запятая. Это первое.

Второе. Ты и в модуле и в основной программе описываешь тип matr. Зачем? Проблемы нужны? Вот ты их и получил: тот тип matr, что описан в модуле, и тот, что описан в основной программе - РАЗНЫЕ типы, хотя и очень похожи. Они несовместимы, и пока ты не уберешь описание типа matr из основной программы, программа компилироваться не будет.

Ну, и третье - вот я не понимаю, зачем передавать в процедуру параметр, который не будет внутри нее использоваться? Опиши K, как локальную переменную, и пусть процедура принимает только один параметр - саму матрицу.

[Юрий]

там должна стоять точка с запятой, а не запятая. Это первое.

Невнимательность, спасибо.

Ну, и третье - вот я не понимаю, зачем передавать в процедуру параметр, который не будет внутри нее использоваться? Опиши K, как локальную переменную, и пусть процедура принимает только один параметр - саму матрицу.

Это я и начал пытаться делать в первом листинге

Второе. Ты и в модуле и в основной программе описываешь тип matr. Зачем? Проблемы нужны? Вот ты их и получил: тот тип matr, что описан в модуле, и тот, что описан в основной программе - РАЗНЫЕ типы, хотя и очень похожи. Они несовместимы, и пока ты не уберешь описание типа matr из основной программы, программа компилироваться не будет.

Вот это и была моя главная ошибка, на которую убил целый день. Огромное спасибо за помощь!