Вывод всех возможных перестановок строки Abc Опции

[Natalia]

Доброго времени суток!
Долго пыталась решить задачу: вдоль, поперёк, с помощью научного тыка, с помощью книг и интернета, поиском в FAQ, перерыла весь форум. Не могу понять задачу. Не понимаю смысла в процедуре рекурсии.
Задача следующая:
Вывести на экран все возможные перестановки строки символов, вводимых с клавиатуры. Например, ввожу "abc", а мне должно быть выведено шесть его перестановок: abc,cba,cab и т. п.
Я её написала для трёх букв без рекурсии. А с рекурсией бред получается такой:
program recur;
procedure swap(var s:string; i,j:integer);
var ch:char;
begin
ch:=s[i];
s[i]:=s[j];
s[j]:=ch;
end;
procedure rec(s:string;n:integer);
var i:integer;
begin
for i:=1 to n-1 do
begin
swap(s,n,i);
rec(s,n-1);
swap(s,n,i);
writeln(s);
end;
if n=1 then writeln(s);
end;
var s:string;
n:integer;
begin
writeln('‚Введите строку');
readln(s);
rec(s,4);
readln;
end.

Помогите, пожалуйста, понять, как реализуется в программе процедура рекурсии.

[volvo]

Плохо искала... По мотивам: Программа о подстановках

чуть-чуть меняем программу, и...

const
  n: integer = 3;

var
  a: array[0 .. 20] of char;

procedure print(T: integer);
var i: integer;
begin
  for i := 1 to T do write(a[i]:3);
  writeln
end;

procedure swap(var a, b: char);
var T: char;
begin T := a; a := b; b := T end;

procedure solve(T: integer);
var i: integer;
begin
  if T >= n then print(t)
  else
    for i := T + 1 to n do begin
      swap(a[T+1], a[i]);
      solve(T+1);
      swap(a[t+1], a[i])
    end
end;

var
  i: integer;
  s: string;

begin
  readln(s);
  n := length(s);

  for i := 1 to n do a[i] := s[i];
  solve(0)
end.

[Natalia]

Я видела эти перестановки, пыталась просто хотя бы повторить то же самое, но почему-то паскаль выдавал прорву цифр.
Кажется что-то понимаю... Спасибо за помощь.

Сообщение отредактировано: Natalia - 7.11.2006 22:36