Комплексные числа, нахождение косинуса Опции

[valeral]

Помогите закончить задачу

Пусть даны комплексное число z (пара вещественных чисел) и вещественное число Эпсилон > 0. Вычислить с точностью Эпсилон значение следующей комплексной функции:
cos z = z – z^2 /2! + z^4 /4! - … + (-1)^n z^2n /(2n)! + …
^ - это степень

program ComplexCos;

type
complex = record
		re, im: real

		end;
var
Eps: real;
z, res:Complex;

{Функция для определения модуля комплексного числа}
function AbsComplex(z: Complex): real;
begin
AbsComplex := sqrt(str(z.re) + sqr(z. im))
end;

{Процедура сложения двух комплексных чисел}
procedure AddComplex(z1,z2: Complex; var res:Complex);
begin
res.re := z1.re + z2.re;
res.im := z1.im + z2.im;
end;

{процедура умножения двух комплексных чисел}
procedure Multicomplex(z1,z2: Complex; var res:Complex);
begin
res.re := z1.re * z2.re - z1.im * z2.im;
res.im := z1.re * z2.im - z1.im * z2.re
end;

{Процедура деления комплексного числа на вещественное}
procedure DivCoplToReal(var z:Complex; c:real);
begin
if c < ??????????????
	then writeln ('На ноль делить нельзя')
	else
	  begin
	  z.re := z.re / c;
	  z.im := z.im / c
	end
end;

{Процедура вычисления косинуса}
???????????????????????
???????????????????????

end;

begin
{Ввод комплексного числа z}
writeln('Введите комплексное число');
write ('Вещественная часть: ');
readln (z.re);
write ('Комплексная часть: ');
readln (z.im);

{Ввод точности вычеслений}
writeln ('Введите Eps - точность вычеслений' , '(Eps>0)');
repeat
write('Eps=');
readln (Eps);
if Eps <=0 then
	writeln('Неправильно.Повторите ввод.');
until (Eps>0);

{Вычисление косинуса}
?????????????
?????????????

{Вывод результатов}
write ('Комплексное число равно', res.re:5:2);
if res.im>=0 then wtite ('+');
write(res.im:5:2, '*i');
readln
end.

[valeral]

кто нибудь, ну помогите

[Romtek]

В цикле сравнивай старое значение с новым до тех пор, пока модуль разницы не превысит эпсилон.

[valeral]

если б ещё знал как

[Romtek]

Операторов цикла не знаешь? Учи матчасть.

[valeral]

вроде всё!

program ComplexCos;
type
complex = record
re, im: real
end;
var
Eps: real;
z, res:Complex;
{Функция для определения модуля комплексного числа}
function AbsComplex(z: Complex): real;
begin
AbsComplex := sqrt(sqr(z.re) + sqr(z. im))
end;
{Процедура сложения двух комплексных чисел}
procedure AddComplex(z1,z2: Complex; var res:Complex);
begin
res.re := z1.re + z2.re;
res.im := z1.im + z2.im;
end;
{процедура умножения двух комплексных чисел}
procedure Multicomplex(z1,z2: Complex; var res:Complex);
begin
res.re := z1.re * z2.re - z1.im * z2.im;
res.im := z1.re * z2.im - z1.im * z2.re
end;
{Процедура деления комплексного числа на вещественное}
procedure MultCoplToReal(var z:Complex; c:real);
begin
 z.re := z.re * c;
 z.im := z.im * c
end;
{Процедура вычисления косинуса}
Procedure CosZ(z,a: Complex; e: real; var res: Complex);
var {a: real;}
i: integer;
begin
  {write('z=');readln(z);}
{  write('e=');readln(e); }
  Multicomplex(z,z,a);
  MultCoplToReal(a, -1/2);
  i:=1; res:=1+a;
repeat
  i:=i+1;
  a:=a*(-1)*(sqr(z.re) + sqr(z. im))/(2*i)/(2*i-1);
  res:=res+a;
until abs(a)<e;
writeln('cos z = ',res:10:7,' ',cos(z)7);
readln;
end;
begin
{Ввод комплексного числа z}
writeln('Введите комплексное число');
write ('Вещественная часть: ');
readln (z.re);
write ('Комплексная часть: ');
readln (z.im);
{Ввод точности вычеслений}
writeln ('Введите Eps - точность вычеслений' , '(Eps>0)');
repeat
write('Eps=');
readln (Eps);
if Eps <=0 then
writeln('Неправильно.Повторите ввод.');
until (Eps>0);
{Вычисление косинуса}
{CosZ(z,Eps,res);}
{Вывод результатов}
write ('Комплексное число равно', res.re:5:2);
if res.im>=0 then write ('+');
write(res.im:5:2, '*i');
readln
end.

Результат
Введите комплексное число
Вещественная часть:2
Комплексная часть:1
Введите Eps - точность вычеслений (Eps>0)
Eps=1
Комплексное число равно 0,00+ 0,00*i1

Чёт по моему не то

здесь
Комплексное число равно 0,00+ 0,00*i1
после i она просит ещё раз ввод и потом ставит это число рядом с собой получается 0,00+ 0,00*i1, поставить 2 получается 0,00+ 0,00*i2
и почему всё время получается 0,00+ 0,00*i

[volvo]

А что, возведение комплексного числа в квадрат теперь делается так:
sqr(z.re) + sqr(z. im) ??? И с каких пор?

[valeral]

если поставить просто sqr (Z) дала ошибку:
функция SQR с параметрами указанный типов не найдена


что за ошибка, вроде всё проверил

[volvo]

Правильно, потому что Complex - НЕ встроенный тип Турбо Паскаля... А поэтому делаем по-другому: допустим, имеем комплексное число Z = (a + b*i)... Возведем его в квадрат:

sqr(z) = z * z = (a + b*i) * (a + b*i) = a^2 + a*b*i + a*b*i + (b*i)^2 = a^2 + 2*a*b*i - b^2 = (a^2 – b^2) + 2*a*b*i

А что у тебя получилось?

[valeral]

мне её надо где-то вписать в код sqr(z)?
немножко не понял вопроса

Сообщение отредактировано: valeral - 6.06.2006 18:09

[valeral]

Volvo обьясни пожалуйста

[volvo]

Значит, так... Вот рабочая программа для вычисления значения Cos(z) комплексного аргумента разложением в ряд:

Program ZnachCos;

type
  complex = record
    re, im: real;
  end;

procedure GetComplex(var cplx: Complex);
begin
  write('(re) part: '); readln(cplx.re);
  write('(im) part: '); readln(cplx.im);
end;
procedure PutComplex(var cplx: Complex);
const sign: array[boolean] of char = ('+', '-');
begin
  write('(', cplx.re:7:4, sign[cplx.im < 0], abs(cplx.im):7:4, '*i');
end;

function AbsComplex(z: Complex): real;
begin
  AbsComplex := sqrt(sqr(z.re) + sqr(z.im))
end;

procedure AddComplex(z1,z2: Complex; var res:Complex);
begin
res.re := z1.re + z2.re;
res.im := z1.im + z2.im;
end;

procedure Multicomplex(z1,z2: Complex; var res:Complex);
begin
  res.re := z1.re * z2.re - z1.im * z2.im;
  res.im := z1.re * z2.im + z1.im * z2.re;
end;
procedure ScaleComplex(var z:Complex; c:real);
begin
 z.re := z.re * c;
 z.im := z.im * c
end;

Var
 n,k:Integer;
 b,e,p,Eps:real;
 z, a, s, sq: complex;
Begin
  writeln('complex Z = '); GetComplex(z);
  Write('real Eps = '); Readln(Eps);

  n := 2;
  a.re := 1; a.im := 0;
  s.re := 1; s.im := 0;
  MultiComplex(z, z, sq);
  While AbsComplex(a) > Eps do Begin
    MultiComplex(a, sq, a);
    ScaleComplex(a, - 1 / (pred(n) * n));
    AddComplex(s, a, s);
    Inc(n, 2)
  End;
  Writeln('COS(z) = '); PutComplex(s);
End.

Теперь - разбор твоих ошибок (может, еще кому интересно будет)... Первая твоя ошибка - в формуле. Правильное разложение косинуса:
cos z = 1 – z^2 /2! + z^4 /4! - … ,
а не z как у тебя...

Вторая - в реализации операции умножения комплексных чисел... Ты поставил знак "-" вместо нужного плюса:

procedure Multicomplex(z1,z2: Complex; var res:Complex);
begin
res.re := z1.re * z2.re - z1.im * z2.im;
res.im := z1.re * z2.im + z1.im * z2.re; { <--- Здесь у тебя был МИНУС }
end;

Ну, и третье - смотри свою реализацию в repeat ... until, и мою в while. Как говорится, найди 10 отличий...

Проверялось на Z = (2, 1)
при Eps = 0.001
Ответ совпадает с тем, что получено на С++ с использованием <complex.h>

[leahov]

здесь выдало ошибку

const sign: array[boolean] of char = ('+', '-');

[ boolean ] - ожидалось выражение

[leahov]

звиняйте в турбо паскале всё работает! Всём спасибо! Volvo - отдельный благодарчик