Метод квадратичной аппроксимации, вычисление минимума функции Опции

[deymon81]

привет всем. Наткнулся на этот сайт и решил попросить помощи.


Составить программу вычисления минимума функции f(x) на интервале [a,b] с точностью 0.001 методом квадратичной аппроксимации

sin 3x-3sinx [0, 3.5]


P.S. Жду помощи

[Altair]

что за квадратичная апроксимация ?
Первый раз о такой слышу, перерыл сейчас 2 учебника по вычислительной математике, нигде нет такого!
Это я к тому,что дайте хоть информацию по методу. (может он по другому еще как то называется ? )
Вообще минимум как вычисляется ? берется производная, и смотрится где она меняет знак с "-" на "+"...
А вот производную на сетке можно апроксимировать используя саму сеточную функцию.
Там в формуле как раз квадрат есть, может имеется ввиду выч. минимум через апроксимацию производной на сетке ?
(при этом сетка производной будет смещенна относительно основной сетки на пол шага, а величина шага задает точность.)

[volvo]

Олег, если программа на С++ здесь недопустима - скрой сообщение...
http://infobez.net.ru/cpp/alg/quadapprox.php

[Altair]

Ах вот оно что.... полиномиальное приближение!
Я то думал...
Вобщем это задача квадратичной интрерполяции! (именно так она в книгах значиться)!
тогда вопрос решен

[deymon81]

Этот метод еще называется-метод Пауэлла

Ссылочку не дадите?????

[volvo]

Я же привел ссылку в своем предыдущем посте...

[deymon81]

Volvo, вот такая херь появляется:

DriveHost предлагает услуги хостинга сайтов, регистрации доменов, а также некоторые дополнительные услуги. Мы создали для Вас сервис, сочетающий удобство и легкость, качество и скорость, надежность и функциональность.



Хостинг от $0.67
99,7% UpTime
PHP, MySQL, Perl, CGI
FrontPage, Cron, WAP
Бесплатные домены
Dual Xeon 3.0, 2 GB RAM
Неограниченный трафик

[volvo]

Тогда через Google-кеш
Здесь...

Хотя странно... Еще вчера все открывалось...

[deymon81]

Там на С++ написана.....попробую переделать. Спасибо еще раз!!!!

[volvo]

Там на С++ написана...

Вот перевод на Паскаль:

uses crt;

type
  func_type = function(x: double): double;

function f(x: double): double;
begin
  f := exp(x) - 2*x*x*x;
end;

{ поиск минимума методом квадратичной аппроксимации }
function findMinQuadApprox(xs, h, eps1, eps2: double;
  max_step: longint; f: func_type): double;
var
  x, f_x: array[0 .. 2] of double;
  k: longint;
  i_min, i_max: integer;
  xn, f_xn, a1, a2: double;

begin
   x[0] := xs; x[1] := xs + h;

   if f(x[0]) > f(x[1]) then begin
     x[2] := xs + 2 * h
   end
   else begin
     x[2] := xs - h
   end;

   f_x[0] := f(x[0]); f_x[1] := f(x[1]); f_x[2] := f(x[2]);

   for k := 0 to pred(max_step) do begin

      if f_x[0] < f_x[1] then begin

         if f_x[0] < f_x[2] then i_min := 0 else i_min := 2

      end
      else begin

         if f_x[1] < f_x[2] then i_min := 1 else i_min := 2;

      end;

      a1 := (f_x[1] - f_x[0]) / (x[1] - x[0]);
      a2 := 1.0 / (x[2]-x[1])*((f_x[2]-f_x[0]) / (x[2]-x[0])-
                               (f_x[1]-f_x[0]) / (x[1]-x[0]));
      xn := (x[1]+x[0])*0.5-a1/(2*a2);
      f_xn := f(xn);

      if (abs((xn-x[i_min])/xn) < eps1) and
         (abs((f_xn-f_x[i_min])/f_xn) < eps2) then break;

      if f_x[0] >= f_x[1] then begin

         if f_x[0] > f_x[2] then i_max := 0 else i_max := 2;

      end
      else begin

         if f_x[1] > f_x[2] then i_max := 1 else i_max := 2;

      end;

      if f_xn < f_x[i_min] then begin
        x[i_max] := xn;
        f_x[i_max] := f_xn;
      end
      else begin
        x[i_max] := 2*x[i_min]-xn;
        f_x[i_max] := f(x[i_max]);
      end;
   end;

   findMinQuadApprox := xn;
end;

var x: double;
begin
   clrscr;

   x := findMinQuadApprox(10, 0.1, 0.00001, 0.00001, 100, f);
   writeln('x    = ', x:10:6);
   writeln('f(x) = ', f(x):10:6);
   readln;
end.