Процедура Опции

[Client]

имеется программа, надо определить что будет напечатано.

Uses crt;
var
    a,b,c,d:integer;
procedure P(var b:integer; c:integer);
var d:integer;
begin
       a:=5;
       b:=6;
       c:=7;
       d:=8;
       writeln(a,b,c,d)
end;
begin
        a:=1;
        b:=2;
        c:=3;
        d:=4;
        P(a,b);
        writeln(a,b,c,d);
        readkey
end.

Ответ такой:
6678
6234
не могу понять почему 6678 и 6234, насчет 234 как-то вроде понятно, а вто 66 и 6 никак
и какие переменные здесь формальные, а какие параметры?

[volvo]

насчет 234 как-то вроде понятно, а вто 66 и 6 никак

Это называется побочный эффект, и за такой код надо, вообще говоря, отрывать все части тела подряд... Смотри:

У тебя есть ГЛОБАЛЬНЫЕ переменные a, b, c, d... Им ты вначале присваиваешь значения 1, 2, 3, 4 соответственно. С этим все просто... Потом: в процедуру передаются значения A и B, но значение А передается "по ссылке" (в процедуре первый параметр описан, как параметр - переменная, то есть его изменение будет передано в вызывающую программу), а B - "по значению", то еть, как бы ты внутри процедуры второй параметр не менял, в основной части программы он останется таким же, как был на момент вызова процедуры.

Ладно... Теперь - заходим внутри процедуры. Что же за бардак мы тут видим? Первый переданный параметр у нас доступен под именем B, но не забудь, что изменяя его, мы изменяем глобальную переменную А (именно она передана в качестве фактического параметра), так что в результате строчка

a := 5

вообще лишена смысла - в A все равно запишется значение, которое присваивается локальному параметру B в следующей строке. Изменение же С не будет доступно извне, оно касается локального параметра, перекрывающего глобальную переменную C (тебе надо прочитать про области видимости + глобальные/локальные переменные, чтобы во всем этом разобраться как следует).

Возникает вопрос, а почему же D := 8 не изменяет значения глобальной переменной D? Да точно по той же причине: в разделе описания переменных внутри процедуры тоже есть переменная D, и она "заслоняет собой" глобальную. Итого, внутри процедуры имеем:
A(глобальная) = 6;
B(var-параметр, она же глобальная A) = 6;
C(параметр-значение) = 7;
D(локальная переменная процедуры) = 8

Печать выдает именно эти значения...

Теперь возвращается из процедуры назад в основную программу. Что поменялось? Глобальные переменные B, C и D процедурой не были изменены, их значения остались такими же, как и до ее вызова. Изменилась только глобальная переменная A (я уже написал, почему). Теперь она равна 6. Что тебе и печатает WriteLn...

[Client]

спасибо за такой полный ответ
но вопросов становится еще больше
вот

procedure P(var b:integer; c:integer);

здеся b это голабальная? а С тоже как-бы в var-е? или нет? понял что С может измениться толко в процедуре, а вот насчет остальных не понял.
а

var d:integer;

здесь? какая разница между этими var-ами?
все эти переменные используются только в процедуре с именами как и глобальные( прочитал что глобальные используются везде и в поцедцрах, а локальные только в процедурах) но у них адреса разные и вообще это разные переменные. Так?

Первый переданный параметр у нас доступен под именем B, но не забудь, что изменяя его, мы изменяем глобальную переменную А

это из-за P(a,b)?

и за такой код надо, вообще говоря, отрывать все части тела подряд...

задание взал из практикума, который создал мой препод.

тебе надо прочитать про области видимости + глобальные/локальные переменные, чтобы во всем этом разобраться как следует

Обязательно

А процедуры и функции надо применять если один и тот же участок программы (основной) в разных местах?
И в чем разница между процедурой и функцией( пока что знаю что функция имеет значение)?

[volvo]

здеся b это голабальная?

Нет... Здесь B - локальный параметр переменная, который перекрывает глобальную... А параметр C - не в Var-6, Var действует в заголовке процедуры до первой точки с запятой, то есть, относится только к B.

акая разница между этими var-ами?

Разница такая: то, что в заголовке - это ПАРАМЕТР, он принимает значения, которые процедуре передали при вызове. А Var там нужен только для того, чтобы указать, что это - параметр, переданный "по ссылке", изменение его передается наружу. Тот Var, что перед Begin-ом - описание локальных переменных (чувствуешь разницу? Там - параметры, здесь - переменные). Переменная ниоткуда снаружи значения не получает, она известна (и существует) только тогда, когда выполняется процедура. Как только процедура закончилась - стек освобождается, вместе с ним уничтожается и локальная переменная.

это из-за P(a,b)?

Я же написал... Хорошо, еще раз: смотрим на заголовок процедуры... Не смотри на имена параметров. Смотри на их порядковый номер... Первый - Var параметр, второй - обычный параметр-значение. Все. Этого достаточно, чтобы понять, что первый может изменяться, а второй - нет... Теперь смотри на ВЫЗОВ процедуры: первый параметр - глобальная переменная A, второй - глобальная B. из чего делаем вывод, что измениться через параметры может только переменная A...

задание взал из практикума, который создал мой препод.

Одно из двух - либо его надо расстрелять через повешение (если он действительно пишет такие программы), либо он просто хочет запутать студентов, и у него пока это получается... До тех пор, пока ты досконально не разберешься с глобальностью/локальностью, и передачей параметров по ссылке/по значению, для тебя такие вопросы будут очень непростыми...

И в чем разница между процедурой и функцией

В том, что функция возвращает значение, которое можно напрямую использовать в выражениях:

writeln(1 + 2.2 * f); { <--- f - функция }

С процедурой такое не пройдет...

[Client]

еще вопросы будут-срошу
Большое спасибо!!!!

[Client]

а как-нибудь можно в процедуре изменить глобальную переменную С? кроме как при вызове?
ведь есть С локальная и глобальная.
Если в процедуре указываем С-то всегда меняется локальная С?

[TarasBer]

а как-нибудь можно в процедуре изменить глобальную переменную С? кроме как при вызове?
ведь есть С локальная и глобальная.
Если в процедуре указываем С-то всегда меняется локальная С?

Да, меняется только локальная C. А к глобальной напрямую - никак. Правда, можно создать указатель (глобальный) и перед вызовом процедуры указатель направить на глобальное C, а потом в процедуре обратиться к указателю.
Только не нужно это, по моему. Ну ни разу не встречал случая, когда из процедуры надо менять глобальную переменную, название которой используется локальной.

[volvo]

Если в процедуре указываем С-то всегда меняется локальная С?

Я этого не сказал. Я сказал, что локальная переменная "перекрывает" глобальную, то еть, если просто указать обращение к переменной - то да, предпочтение будет отдано локальной. Но и к глобальной тоже есть доступ:

program test;

var A: integer;

procedure proc(A: integer);
begin
  writeln(A); { <--- это печатается локальная переменная }
  writeln(test.A); { <--- а это - глобальная (обрати внимание на способ обращения) }
end;

begin
  A := 10;
  proc(50);
end.

Добавлено через 1 мин.
TarasBer - дезинформация чистой воды...

[TarasBer]

Добавлено через 1 мин.
TarasBer - дезинформация чистой воды...

Извиняюсь, да. Но по-моему, это скорее ложь во спасение, чем дезинформация. Чтобы не путаться.

[Client]

Правда, можно создать указатель

а это как?
А еще препод сегодня сказал, что надо стараться использовать параметры-перменные(из-за экономии памяти и времени)
Насколько правильно это?

Сообщение отредактировано: Client - 4.12.2007 21:11

[Lapp]

а это как?

Вообще-то, лучше делать так, как написал volvo. И если ты еще не знаешь, что такое указатель (pointer), то рекомендую обратиться к какому-нить учебнику. Вряд ли стоит здесь приводить пролные сведения об этом. Кратко же, примерно так:

var
  a: integer;
  pa: ^integer

procedure P(a:integer);
begin
  WriteLn(pa^);
end;

begin
  pa:= Addr(a);
  a:=0;
  P(1)
end;

Повторяю: лучше делать способом volvo. Но если уж все же хочется извращаться, то все равно способ TarasbBer несколько неуклюж, а также требует лишней памяти и времени. И если уж все-таки хочется извращаться, то лучше через absolute:

var
  a: integer;
  b: integer absolute a;

procedure P(a: integer);
begin
  WriteLn(a);
  WriteLn(b);
end;

begin
  a := 10;
  P(50);
end.

А еще препод сегодня сказал, что надо стараться использовать параметры-перменные(из-за экономии памяти и времени)
Насколько правильно это?

Думаю, речь идет о передаче параметров "по адресу" (var).
Очень ограниченно правильно.
Передача параметров "по значению" - это одно из основных преимуществ Паскаля. Я помню, как я мучился в начале своей программерской деятельности, пытаясь найти ошибку в программе на Фортране. Убил несколько дней (тогда персоналок не было, я работал на большой машине и мог запустить прогу всего несколько раз в день), но нашел. Оказалось, что я вызываю процедуру с параметром 1, а в процедуре изменяю этот параметр. На результаты процедуры это не влияло, но из-за этого портилась сама единица! И когда я потом присваивал какой-нить переменной единицу, ей присваивалось нечто другое.. ))

Передача параметров "по значению" гарантирует их сохранность в вызывающей процедуре. Так что эту переменную в некоторых случаях можно использовать для хранения промежуточных значений - что тоже может сэкономить память. Очень рекомендую пользоваться этим преимуществом хотя бы на этапе отладки и для переменных, не требующих большой памяти. Если уж так важно время и так жестки требования к памяти, то после отладки можно поменять способ передачи - но не забыть ОБЯЗАТЕЛЬНО ПРОВЕРИТЬ программу снова как следует!

В некоторых случаях, когда параметр сам по себе требует много памяти (типа массив в килобайты), волей-неволей приходиться использовать вызов "по адресу", так как в противном случае просто не хватит памяти, а также исполнение резко замедлится. Это лишний раз говорит о том, что к программированию нужно подходить творчески. Я думаю, ваш учитель имел в виду именно случай больших по объему переменных.

[Client]

Способ volvo лучше и я не спорю. Не помешает узнать еще что-нибудь об этом
В теме надо найти ошибку в задаче из 3 подпрограмм(2 не выполняются при запуске) volvo сказал что там в цикле используется глобальная переменная, разве ее там не перекрывает локальная? В процедуре Sum да, используется глобальная, а в функции poisk локальная?

Сообщение отредактировано: Client - 5.12.2007 7:35

[Lapp]

там в цикле используется глобальная переменная, разве ее там не перекрывает локальная? В процедуре Sum да, используется глобальная, а в функции poisk локальная?

В процедуре poisk - да, перекрывает, а в процедурах sum и upor - глобальные переменные цикла.

[volvo]

Думаю, речь идет о передаче параметров "по адресу" (var).

Кстати, есть еще так называемая "передача по константной ссылке" (через Const). Вот это - вообще незаменимый способ передаци объектов, которые не должны изменяться внутри водпрограммы (Хотя все-таки есть способ изменить и переданные по Const параметры, но это опять же требует дополнительных усилий, и свидетельствует только о непреодолимой тяге программиста к созданию себе же самому проблем).

Ну, к примеру, есть у меня процедура печати массива... А массив описан как

const
  bufSize = 2048;
type 
  bufType = array[1 .. bufSize] of byte;

{ ну, вот сразу и сама процедура: }
procedure print_arr(var f: text; arr: arrType);
begin
  for i := 1 to bufSize do write(f, arr[i]:4);
  writeln(f);
end;

Что получаем? Ничего особенного: за гарантию того, что массив, переданный в процедуру как arr, в вызывающей программе останется неизменным - заплатили отъеданием 2К из стека (поскольку параметр "по значению" передается через стек), а стек не резиновый, там всего 16К по умолчанию.

Можно, конечно, передать его по ссылке, и сэкономить тем самым 2К стека:
procedure print_arr(var f: text; var arr: arrType);

Здесь возникает другая проблема: ну ладно здесь, все видно, никаких попыток изменения массива arr нет. Будет процедура раз в 5 длиннее - можно и не заметить попытки изменения. Поэтому все-таки я бы рекомендовал передачу через Const, когда надо гарантировать неизменность данных; тогда и стек экономится (в процедуру передается не весь массив, а ссылка на него), и при малейшей попытке (случайной, разумеется) изменить содержимое массива компилятор покажет, где именно это происходит и откажется компилировать программу дальше...

[Client]

Спасибо!
И откуда вы все это знаете?

[volvo]

"И опыт, сын ошибок трудных..." (С) А.С. Пушкин...