Пожалуйста, подскажите, как можно написать прогу, изменяющую порядок байтов в файле, так, что последний байт становится первым, и наоборот, причём программа должна работать с файлами разной длины

Имеешь в виду поменять местами 1 и последнее значение в типизированном

File of Byte

или что ?

ps название темы поменяй, иначе придется закрыть.

Нет, ну например, 12345 сделать 52341

Файл у тебя как описан ? Text или file of byte ?

По-совему усмотрению. И вообще, допускаются любые разумные ограничения, но их нужно указать

Например так:

uses crt;

type
  TFile = File of Byte;

procedure CreateFile(fName: String; n: Integer);
var
  f: TFile;
  i: Integer;
begin
  Randomize;
  Assign(f, fName);
  Rewrite(f);
  for i := 1 to n do
   write(f, Random(256));
  Close(f);
end;

procedure Display(fName: String);
var
  f: TFile;
  T: Byte;
begin
  writeln;
  Assign(f, fName);
  Reset(f);
  while not eof (f) do begin
    read(f, T);
    writeln(T);
  end;
  Close(f);
end;

procedure Restructure(fName: String);
var
  f, f1: TFile;
  i: Integer;
  T: Byte;
begin
  Assign(f, fName);
  Assign(f1, 'temp');
  Reset(f);
  Rewrite(f1);
  for i := FileSize(f) - 1 downto 0 do begin
    Seek(f, i);
    read(f, T);
    write(f1, T);
  end;
  Close(f);
  Close(f1);
  Erase(f);
  Rename(f1, fName);
end;

const
  fName = 'c:\test.bt';

begin
  clrscr;

  CreateFile(fName, 10);
  Display(fName);
  Restructure(fName);
  Display(fName);

  readln;
end.
 

Спасибо огоромное!!!

М

Незачто, читай FAQ: Файлы. И не надо делать такие большие цитаты