помогите написать программу заполнения массива по принципу (лесенкой):

0   0   0   8   9   0   0   0
0   0   6   7  11  10   0   0
0   4   5  13  12  26  27   0
2   3  15  14  24  25  29  28
1  17  16  22  23  31  30  40
0  18  20  21  33  32  39   0
0   0  19  35  34  38   0   0
0   0   0  36  37   0   0   0

Юля, я не знаю, кто из вас ошибается в постановке условия, но только оно неправильное.
Последний ряд (37, 38, 39, 40) - это никакая не "лесенка"! Я написал программу заполнения _лесенкой_, но только последний ряд она заполняет, конечно, НЕ ТАК. Она на самом деле вообще выходит за границы массива, потому что по лесенке 37 должно стоять на позиции [9,5]. И я не хочу тут выкладывать прогу, которая вылетает по ошибке (и не по моей, а кого-то из вас). Так что ты уточни условие, пожалуйста - тогда поговорим..

P.S.
чтобы матрица была ровной, создавай ее, пожалуйста, в Блокноте и копируй сюда, а потом окружай тегами CODE. Сейчас я исправил, но в след раз сама давай - Okay?

Добавлено через 16 мин.
Упс!! Сейчас посмотрел повнимательнее картинку, и увидел, что это в ней предусмотрено.. Значит, зря я катил бочку на твоего препа, извиняюсь )). Но ты (бяка) должна была хотя бы упомянуть (словами), что последний ряд отличается от всех остальных..

Ладно, тогда я выложу код . Но только - без последнего ряда! Была заказана лесенка - получи лесенку и распишись

// код удален, см. ниже исправленный вариант

Сообщение отредактировано: Lapp - 1.12.2011 7:07

Спасибо огромное и на этом ) признаю, виновата
и в дальнейшем учту свои ошибки в оформлении)

Вау! Редчайшая ситуация: юзер соглашается с критикой и не качает права!
Ладно, тогда я тоже признаю свои ошибки: не надо было спойлить обучение хорошего человека и давать ему почти полное решение. А также - продолжу их делать..

Юляша, чтобы сделать заполнение последнего ряда, нужно вставить отдельный цикл (см. ниже). Кроме прочего, я сделал в некотором роде ошибку (заполнение было неправильное для n, не кратным 4). Вот код, в котором все вроде правильно..

{ a stairway to heaven, leading down
  by Lapp, forum.pascalnet.ru (forum.pascalnet.ru)
  for Yulyasha }

const
  n= 14;   // even numbers only!

var
  a: array[1..n,1..n]of integer;
  b,i,j,di,dj,z,count: integer;

procedure Show;
var
  i,j: integer;
begin
  for i:=1 to n do begin
    for j:=1 to n do write(a[i,j]:3);
    writeln
  end;
end;

begin
  i:= n div 2+1;
  j:= 1;
  di:= 1;
  dj:= 0;
  z:= 1;
  count:= 1;
  repeat
    // writeln(i:10,j:10,count:10); show;
    a[i,j]:= count;
    Inc(count);
    if (j-i)*z=n div 2 then begin
      i:= i+1;
      j:= j+1;
      z:= -z;
      b:= di;
      di:= -dj;
      dj:= -b
    end
    else begin
      i:= i-di;
      j:= j+dj;
      di:= z-di;
      dj:= z-dj
    end
  until (i>n) or (j>n);
  // filling in the last row (straight)
  i:= i+dj;
  j:= j-di;
  repeat
    i:= i-di-dj;
    j:= j+di+dj;
    a[i,j]:= count;
    Inc(count)
  until count>n*n div 2+n;
  Show;
  readln
end.

Успехов тебе. Что неясно - спрашивай.